;**************************************************************************
; FILE:      dazzler.asm                                                  *
; CONTENTS:  'Razzle Dazzler'                                             *
; COPYRIGHT: MadLab Ltd. 1999-2003                                        *
; AUTHOR:    James Hutchby                                                *
; UPDATED:   09/11/03                                                     *
;**************************************************************************

     list p=12C508

     include "p12c508.inc"

     __config _IntRC_OSC & _WDT_OFF & _MCLRE_OFF & _CP_ON

     __idlocs h'AE21'

     errorlevel -305

; N.B. '508 (2.5V min Vdd) rather than '508A (3.0V min Vdd)


;**************************************************************************
;                                                                         *
; Specification                                                           *
;                                                                         *
;**************************************************************************

; power-up self-test - all LED's flash twice
; button pressed when power applied -> step sequence mode
; else -> random sequence mode
; button pressed and released -> sequence mode
; button held down for ~2 seconds -> setup mode

; setup mode :-
;   button held down -> brightness cycles
;   button released -> sequence mode

; sequence mode :-
;   button pressed -> next sequence if step mode + sleep mode


;**************************************************************************
;                                                                         *
; Port assignments                                                        *
;                                                                         *
;**************************************************************************

GPIO_IO   equ       b'001000'      ; GPIO I/O status

BUTTON    equ       3              ; pushbutton

LED0      equ       4              ; LED #0
LED1      equ       d'8'+4         ; LED #1
LED2      equ       5              ; LED #2
LED3      equ       d'8'+5         ; LED #3
LED4      equ       1              ; LED #4
LED5      equ       d'8'+1         ; LED #5
LED6      equ       2              ; LED #6
LED7      equ       d'8'+2         ; LED #7

LED_MASK  equ       b'110110'      ; LED mask

LED_MUX   equ       0              ; LED multiplexer


;**************************************************************************
;                                                                         *
; Constants and timings                                                   *
;                                                                         *
;**************************************************************************

CLOCK          equ  d'4000000'     ; processor clock frequency in Hz

PRESCALE       equ  b'00000000'    ; prescale RTCC 1:2 (weak pull-ups
                                   ; enabled, wake-up on pin change)

FLASH_PERIOD   equ  d'150'         ; LED flash period
POLL_PERIOD    equ  d'7'           ; button poll period
SETUP_PERIOD   equ  d'80'          ; setup mode period
CYCLE_PERIOD   equ  d'20'          ; setup cycle period

SEQUENCES      equ  d'16'          ; number of sequences
BRIGHTNESS     equ  d'4'           ; default brightness


;**************************************************************************
;                                                                         *
; File register usage                                                     *
;                                                                         *
;**************************************************************************

RAM  equ  h'07'

     cblock RAM
     mode                     ; mode (bit 0 = setup, bit 1 = step)
     brightness               ; LED brightness, 1 to 8
     pattern                  ; LED pattern
     LEDS_A, LEDS_B           ; port data
     delay                    ; delay
     timer                    ; timer
     rand_l, rand_h           ; random number
     speed                    ; speed
     repeat                   ; repeat count
     step                     ; sequence index
     count1, count2           ; scratch counters
     work1, work2             ; work registers
     endc


;**************************************************************************
;                                                                         *
; Macros                                                                  *
;                                                                         *
;**************************************************************************

routine   macro label              ; routine
label
          endm

table     macro label              ; define lookup table
label     addwf PCL
          endm

entry     macro value              ; define table entry
          retlw value
          endm

index     macro label              ; index lookup table
          call label
          endm

jump      macro label              ; jump through table
          goto label
          endm

tstw      macro                    ; test w register
          iorlw 0
          endm

movff     macro f1,f2              ; move file to file
          movfw f1
          movwf f2
          endm

movlf     macro n,f                ; move literal to file
          movlw n
          movwf f
          endm


;--------------------------------------------------------------------------
; reset vector
;--------------------------------------------------------------------------

          org 0

          movwf OSCCAL

          goto main_entry


;**************************************************************************
;                                                                         *
; Lookup tables                                                           *
;                                                                         *
;**************************************************************************

          table seq_jump                ; sequence jump table

          goto seq1
          goto seq2
          goto seq3
          goto seq4
          goto seq5
          goto seq6
          goto seq7
          goto seq8
          goto seq9
          goto seq10
          goto seq11
          goto seq12
          goto seq13
          goto seq14
          goto seq15
          goto seq16


          table repeats                 ; repeat counts

          entry d'4'
          entry d'45'
          entry d'12'
          entry d'12'
          entry d'5'
          entry d'1'
          entry d'18'
          entry d'12'
          entry d'3'
          entry d'24'
          entry d'8'*d'10'
          entry d'8'*d'7'
          entry d'11'
          entry d'7'
          entry d'8'*d'8'
          entry d'8'*d'6'


          table patterns                ; initial patterns

          entry b'01000100'
          entry b'00000001'
          entry b'00000000'
          entry b'00000000'
          entry b'01000100'
          entry b'01010101'
          entry b'00000000'
          entry b'00000000'
          entry b'00000001'
          entry b'00001001'
          entry b'00000001'
          entry b'00001111'
          entry b'00000000'
          entry b'00000000'
          entry b'00000001'
          entry b'00000001'


          table speeds                  ; initial speeds

          entry d'22'
          entry d'22'
          entry d'12'
          entry d'22'
          entry d'15'
          entry d'27'
          entry d'15'
          entry d'16'
          entry d'28'
          entry d'30'
          entry d'44'
          entry d'60'
          entry d'21'
          entry d'26'
          entry d'35'
          entry d'35'


          table pattern3

          entry b'10000010'
          entry b'10000010'
          entry b'01000100'
          entry b'01000100'
          entry b'00101000'
          entry b'00101000'
          entry b'00010000'
          entry b'00010000'
          entry b'00010000'
          entry b'00101000'
          entry b'00101000'
          entry b'01000100'
          entry b'01000100'
          entry b'10000010'
          entry b'10000010'
          entry b'00000001'
          entry b'00000001'
          entry b'00000001'

len3      equ  $-pattern3-1


          table pattern4

          entry b'00000001'
          entry b'10000011'
          entry b'11000111'
          entry b'11101111'
          entry b'11111111'
          entry b'11111110'
          entry b'01111100'
          entry b'00111000'
          entry b'00010000'
          entry b'00000000'

len4      equ  $-pattern4-1


          table pattern7

          entry b'10001000'
          entry b'10011001'
          entry b'10111011'
          entry b'11111111'
          entry b'01110111'
          entry b'01100110'
          entry b'01000100'
          entry b'00000000'
          entry b'00000000'

len7      equ  $-pattern7-1


          table pattern13

          entry b'10000011'
          entry b'11000110'
          entry b'01101100'
          entry b'00111000'
          entry b'00010000'
          entry b'00010000'
          entry b'00111000'
          entry b'01101100'
          entry b'11000110'
          entry b'10000011'
          entry b'00000001'
          entry b'00000001'

len13     equ  $-pattern13-1


          table pattern14

          entry b'00010001'
          entry b'10101010'
          entry b'01000100'
          entry b'10101010'
          entry b'00010001'
          entry b'00000000'
          entry b'00000000'
          entry b'01000100'
          entry b'10101010'
          entry b'00010001'
          entry b'10101010'
          entry b'01000100'
          entry b'00000000'
          entry b'00000000'

len14     equ  $-pattern14-1


;**************************************************************************
;                                                                         *
; Procedures                                                              *
;                                                                         *
;**************************************************************************

;--------------------------------------------------------------------------
; tests the button
;--------------------------------------------------------------------------

test_button    macro

          movlw 1<<BUTTON
          movwf GPIO
          nop
          andwf GPIO,w                  ; Z flag set if button pressed

          endm


;--------------------------------------------------------------------------
; generates a pseudo random number in the range 0 to 15
;--------------------------------------------------------------------------

get_random     macro

          movfw rand_l
          iorwf rand_h,w
          bnz getr1

          movfw TMR0                    ; seed generator
          movwf rand_l
          xorlw h'ff'
          movwf rand_h

getr1     rlf rand_h,w                  ; calculate next in sequence
          xorwf rand_h,w
          movwf work2                   ; msb <= Q15 ^ Q14
          swapf rand_l,w
          btfsc rand_h,4
          xorlw h'80'                   ; msb <= Q12 ^ Q3
          xorwf work2
          rlf work2
          rlf rand_l
          rlf rand_h                    ; << 1 + (Q15 ^ Q14 ^ Q12 ^ Q3)

          movfw rand_l
          andlw h'0f'

          endm


;--------------------------------------------------------------------------
; polls the button
;--------------------------------------------------------------------------

          routine poll_button

          movlw POLL_PERIOD
          call duty_cycle

          test_button

          retlw 0


;--------------------------------------------------------------------------
; duty cycle
;--------------------------------------------------------------------------

          routine wait

          movfw speed
          addwf speed,w
          goto duty_cycle


          routine pause

          movfw speed
;         goto duty_cycle


          routine duty_cycle

          movwf delay

          movlw PRESCALE                ; prescale RTCC
          option

          movlw GPIO_IO                 ; re-initialise port
          tris GPIO

do_bit    macro bit,led
          btfsc pattern,bit
          if led < d'8'
          bsf LEDS_A,led
          else
          bcf LEDS_B,led-d'8'
          endif
          endm

          clrf LEDS_A                   ; determine port I/O data
          movlw LED_MASK|(1<<LED_MUX)
          movwf LEDS_B
          do_bit 0,LED0
          do_bit 1,LED1
          do_bit 2,LED2
          do_bit 3,LED3
          do_bit 4,LED4
          do_bit 5,LED5
          do_bit 6,LED6
          do_bit 7,LED7

duty1     movlf d'16'<<3,work1

duty2     decf work1

          movfw work1                   ; determine duty cycle phase
          andlw d'15'
          decf brightness
          subwf brightness,w
          incf brightness

          movfw LEDS_A                  ; pulse LED's
          btfss work1,4
          movfw LEDS_B
          skpc
          clrw
          movwf GPIO

          tstf work1
          bnz duty2

          decfsz delay
          goto duty1

          clrf GPIO                     ; LED's off

          btfsc mode,0                  ; sequence mode ?
          goto duty4                    ; branch if not

          test_button                   ; button pressed ?
          bnz duty4                     ; branch if not

          btfss mode,1                  ; step mode ?
          goto duty3                    ; branch if not

          incf step                     ; next sequence
          movlw SEQUENCES
          subwf step,w
          skpnz
          clrf step

duty3     goto wait_release

duty4     retlw 0


;--------------------------------------------------------------------------
; rotates a pattern
;--------------------------------------------------------------------------

          routine crotate

          movwf count1

crot1     call wait

          rlf pattern,w
          rlf pattern

          decfsz count1
          goto crot1

          retlw 0


          routine arotate

          movwf count1

arot1     call wait

          rrf pattern,w
          rrf pattern

          decfsz count1
          goto arot1

          retlw 0


;--------------------------------------------------------------------------
; main entry point
;--------------------------------------------------------------------------

          routine main_entry

          clrf GPIO                     ; initialise port
          movlw GPIO_IO
          tris GPIO

          btfsc STATUS,GPWUF            ; wake-up on pin change ?
          goto main0                    ; branch if yes

          movlf BRIGHTNESS,brightness   ; default brightness

          clrf step                     ; first sequence

          clrf rand_l                   ; clear random number
          clrf rand_h

          bsf mode,0                    ; self test
          movlf h'ff',pattern
          movlw FLASH_PERIOD
          call duty_cycle
          clrf pattern
          movlw FLASH_PERIOD
          call duty_cycle
          movlf h'ff',pattern
          movlw FLASH_PERIOD
          call duty_cycle
          clrf pattern

          bcf mode,1                    ; step mode if button pressed
          call poll_button
          bnz sleep_mode
          bsf mode,1
          goto wait_release

main0     movlw PRESCALE                ; prescale RTCC
          option

          call poll_button              ; button pressed ?
          bnz sleep_mode                ; branch if not

          clrf pattern
          bsf mode,0

          movlf SETUP_PERIOD,timer      ; initialise timer

main1     call poll_button              ; button released ?
          bnz sequence                  ; branch if yes

          decfsz timer
          goto main1

          goto setup                    ; setup if timeout


;--------------------------------------------------------------------------
; wait for the button to be released
;--------------------------------------------------------------------------

          routine wait_release

          clrf pattern
          bsf mode,0

wait1     call poll_button
          bz wait1

;         goto sleep_mode


;--------------------------------------------------------------------------
; sleep mode
;--------------------------------------------------------------------------

          routine sleep_mode

          clrf GPIO                     ; LED's off

          movfw GPIO                    ; read port

          sleep                         ; standby mode


;--------------------------------------------------------------------------
; setup brightness
;--------------------------------------------------------------------------

          routine setup

          bsf mode,0                    ; signal setup mode

          movlf CYCLE_PERIOD,timer      ; initialise timer

setup1    movff brightness,work1        ; determine pattern
          clrf pattern                  ; (1 to 8 LED's on)
setup2    setc
          rlf pattern
          decfsz work1
          goto setup2

          call poll_button              ; button released ?
          bnz sequence                  ; branch if yes

          decfsz timer
          goto setup1

          bcf brightness,3              ; increment brightness
          incf brightness               ; (1 to 8)

          goto setup                    ; loop


;--------------------------------------------------------------------------
; different sequences
;--------------------------------------------------------------------------

          routine seq1

          movlw d'4'
          call crotate
          call pause
          movlw d'4'
          call arotate
          call pause

          movlw d'4'+d'16'
          call crotate
          call wait

          movlw d'4'
          call arotate
          call pause
          movlw d'4'
          call crotate
          call pause

          movlw d'4'+d'16'
          call arotate
          call wait

          goto seq_loop


          routine seq2

          movlw d'8'*2
          call crotate

          decf speed
          skpnz
          incf speed

          goto seq_loop


          routine seq3

          movlf len3,count1

seq3a     decf count1,w
          index pattern3
          movwf pattern

          call wait

          decfsz count1
          goto seq3a

          goto seq_loop


          routine seq4

          movlf len4,count1

seq4a     decf count1,w
          index pattern4
          movwf pattern

          call wait

          decfsz count1
          goto seq4a

          call pause

          goto seq_loop


          routine seq5

          movlw d'8'*d'4'
          call crotate
          call wait

          movlw d'8'*d'4'
          call arotate
          call wait

          goto seq_loop


          routine seq6

          movlw d'8'*d'10'
          call crotate

          goto seq_loop


          routine seq7

          movlf len7,count1

seq7a     decf count1,w
          index pattern7
          movwf pattern

          call wait

          decfsz count1
          goto seq7a

          goto seq_loop


          routine seq8

seq8a     call wait

          setc
          rlf pattern
          bnc seq8a

seq8b     call wait

          clrc
          rlf pattern
          bc seq8b

          goto seq_loop


          routine seq9

          movlf d'28',speed

          movlf d'1',count2

seq9a     movfw count2
          call crotate
          call pause
          movfw count2
          addwf count2,w
          call arotate
          call pause
          movfw count2
          call crotate

          movlw d'2'
          subwf speed

          incf count2
          movlw d'9'
          subwf count2,w
          bnz seq9a

          goto seq_loop


          routine seq10

          movlw d'8'
          call crotate

          decf speed

          goto seq_loop


          routine seq11

          call wait

          swapf pattern

          call wait

          swapf pattern

          rlf pattern,w
          rlf pattern

          movlw d'10'
          subwf speed,w
          skpz
          decf speed

          goto seq_loop


          routine seq12

          call wait

          comf pattern
          rlf pattern,w
          rlf pattern

          decf speed

          goto seq_loop


          routine seq13

          movlf len13,count1

seq13a    decf count1,w
          index pattern13
          movwf pattern

          call wait

          decfsz count1
          goto seq13a

          goto seq_loop


          routine seq14

          movlf len14,count1

seq14a    decf count1,w
          index pattern14
          movwf pattern

          call wait

          decfsz count1
          goto seq14a

          goto seq_loop


          routine seq15

          movlf d'3',count2

seq15a    movlw d'1'
          call crotate
          movlw d'1'
          call arotate

          decfsz count2
          goto seq15a

          movlw d'1'
          call crotate

          movlw d'3'
          subwf speed,w
          skpz
          decf speed

          goto seq_loop


          routine seq16

          movlf d'3',count2

seq16a    movlw d'2'
          call crotate
          movlw d'1'
          call arotate

          decfsz count2
          goto seq16a

          movlw d'3'
          subwf speed,w
          skpz
          decf speed

          goto seq_loop


;--------------------------------------------------------------------------
; start sequence
;--------------------------------------------------------------------------

          routine sequence

          bcf mode,0                    ; signal sequence mode

          clrf pattern                  ; poll delay
          call poll_button

          clrf repeat


          routine seq_loop

          tstf repeat
          bnz loop2

          clrf pattern
          movlw d'150'
          call duty_cycle

          movlw GPIO_IO                 ; re-initialise port
          tris GPIO

          movlw PRESCALE                ; prescale RTCC
          option

          btfsc mode,1                  ; step mode ?
          goto loop1                    ; branch if yes

          get_random                    ; select a sequence at random
          movwf step

loop1     movfw step                    ; get repeat count
          index repeats
          movwf repeat

          movfw step                    ; get initial pattern
          index patterns
          movwf pattern

          movfw step                    ; get initial speed
          index speeds
          movwf speed

loop2     decf repeat

          movfw step
          goto seq_jump


;         org h'1ff'                    ; *** comment for OTP part ***
;         goto main_entry


          end