;**************************************************************************
; FILE:      drummer.asm                                                  *
; CONTENTS:  'Funky Drummer' drum machine                                 *
; COPYRIGHT: MadLab Ltd. 1998                                             *
; AUTHOR:    James Hutchby                                                *
; UPDATED:   15/01/99                                                     *
;**************************************************************************

     list p=16C54

     ifdef __16C54
     include "p16c5x.inc"
     endif
     ifdef __16C84
     include "p16c84.inc"
     endif

     ifdef __16C54
     __config _HS_OSC & _WDT_ON & _CP_ON
     endif
     ifdef __16C84
     __config _HS_OSC & _WDT_ON & _PWRTE_ON & _CP_ON
     endif

     __idlocs h'BB10'


;**************************************************************************
;                                                                         *
; Specification                                                           *
;                                                                         *
;**************************************************************************

; PIC16C54,84 - Osc: HS, WDT: On, PuT: On

; mode button + drum/rhythm/record button changes mode

; drum mode:
;  touch switches play drum samples in banks of 4
;  bank button cycles through drum banks
;  tempo buttons ignored

; rhythm mode:
;  touch switches play rhythms in banks of 4
;  bank button cycles through rhythm banks
;  tempo buttons increase or decrease tempo
;  LED flashes at start of loop

; record mode:
;  metronome click on 4 beats
;  touch switches record drum samples in banks of 4 (first 15 only)
;  bank button cycles through drum banks
;  tempo buttons increase or decrease tempo
;  record button stops metronome but user rhythm continues
;  records a maximum of 11 user events


;**************************************************************************
;                                                                         *
; Port assignments                                                        *
;                                                                         *
;**************************************************************************

PORTA_IO       equ       b'0100'        ; port A I/O status
PORTB_IN       equ       b'11111111'    ; port B IN status
PORTB_OUT      equ       b'00000000'    ; port B OUT status

ADDR_PORT      equ  PORTB               ; ISD address port

#define   PLAYL          PORTA,0        ; play level
#define   PLAYE          PORTA,3        ; play edge
#define   RECLED         PORTA,2        ; record LED
#define   LED            PORTA,1        ; LED

BUTTONS_PORT   equ  PORTB               ; buttons port

TOUCH1         equ  3                   ; touch switch #1
TOUCH2         equ  2                   ; touch switch #2
TOUCH3         equ  1                   ; touch switch #3
TOUCH4         equ  0                   ; touch switch #4
MODE           equ  4                   ; mode select
DRUM           equ  5                   ; drum mode
RHYTHM         equ  6                   ; rhythm mode
RECORD         equ  7                   ; record mode
SELECT         equ  5                   ; drum/rhythm bank
FAST           equ  6                   ; faster tempo
SLOW           equ  7                   ; slower tempo


;**************************************************************************
;                                                                         *
; Constants and timings                                                   *
;                                                                         *
;**************************************************************************

CLOCK     equ  d'4000000'     ; processor clock frequency in Hz

DEBOUNCE  equ  d'50'          ; ISD debounce period in ms

DRUM_BANKS     equ  d'10'     ; number of drum banks
RHYTHM_BANKS   equ  d'3'      ; number of rhythm banks

TIMER_MASK     equ  h'1f'     ; timer mask

TEMPO_MIN      equ  d'50'     ; minimum tempo
TEMPO_MAX      equ  d'3'      ; maximum tempo
TEMPO_INIT     equ  d'20'     ; initial tempo


;--------------------------------------------------------------------------
; drum indexes
;--------------------------------------------------------------------------

     cblock 0
     BEEP                     ; beep

     CL_HIHAT                 ; closed hihat
     LO_TOM1                  ; low tom #1
     SNARE1                   ; snare #1
     BASS1                    ; bass #1

     OP_HIHAT                 ; open hihat
     LO_TOM2                  ; low tom #2
     SNARE2                   ; snare #2
     BASS2                    ; bass #2

     CRASH                    ; crash cymbal
     TAIKO                    ; taiko
     SNARE3                   ; snare #3
     BASS3                    ; bass #3

     HI_TOM3                  ; high tom #3
     HI_TOM2                  ; high tom #2
     HI_TOM1                  ; high tom #1
     SNARE4                   ; snare #4

     HI_CONGA                 ; high conga
     LO_CONGA                 ; low conga
     HI_BONGO                 ; high bongo
     LO_BONGO                 ; low bongo

     TIMPANI                  ; timpani
     TIMBALE                  ; timbale
     HI_AGOGO                 ; high agogo
     LO_AGOGO                 ; low agogo

     CHINA                    ; china cymbal
     CABASA                   ; cabasa
     BRUSH2                   ; brush #2
     BRUSH1                   ; brush #1

     SNAP                     ; snap
     CLAP                     ; clap
     COWBELL                  ; cowbell
     TRIANGLE                 ; triangle

     GUNSHOT                  ; gunshot
     SCRATCH                  ; scratch
     WHISTLE                  ; whistle
     KALIMBA                  ; kalimba

     RIMSHOT                  ; rimshot
     CHICKEN                  ; chicken
     BUBBLE                   ; bubble
     QUIJADA                  ; quijada

     endc

CLICK     equ  RIMSHOT        ; metronome click


;**************************************************************************
;                                                                         *
; File register usage                                                     *
;                                                                         *
;**************************************************************************

     ifdef __16C54
RAM  set  h'07'
     endif
     ifdef __16C84
RAM  set  h'0c'
     endif

     cblock RAM
     flags               ; various flags
     buttons             ; buttons pressed, 0 if none
     buttons_            ; previous buttons pressed
     banks               ; banks (bits 7-4 = rhythm, bits 3-0 = drum)
     timer               ; tempo timer
     tempo               ; rhythm tempo
     sustain             ; drum sustain
     rhythm_pnt          ; rhythm pointer
     count               ; scratch counter
     work                ; work register
     buffer              ; user rhythm buffer
     endc
     cblock buffer
     rhythm_start        ; rhythm start
     endc

buffer_end     equ  h'1f'     ; end of user buffer

; flags
MODE_DRUM      equ  0         ; drum mode
MODE_RHYTHM    equ  1         ; rhythm mode
MODE_RECORD    equ  2         ; record mode
SHIFT          equ  3         ; set if mode button pressed
SHORT          equ  4         ; set if minimum sustain event
TMR            equ  5         ; timer flag


;**************************************************************************
;                                                                         *
; Macros                                                                  *
;                                                                         *
;**************************************************************************

routine   macro label              ; routine
label
          endm

table     macro label              ; define lookup table
label     addwf PCL
          endm

entry     macro value              ; define table entry
          retlw value
          endm

index     macro label              ; index lookup table
          call label
          endm

jump      macro label              ; jump through table
          goto label
          endm

tstw      macro                    ; test w register
          iorlw 0
          endm

movff     macro f1,f2              ; move file to file
          movfw f1
          movwf f2
          endm

movlf     macro n,f                ; move literal to file
          movlw n
          movwf f
          endm

tris_A    macro                    ; tristate port A
          ifdef __16C54
          tris PORTA
          endif
          ifdef __16C84
          bsf STATUS,RP0
          movwf TRISA&h'7f'
          bcf STATUS,RP0
          endif
          endm

tris_B    macro                    ; tristate port B
          ifdef __16C54
          tris PORTB
          endif
          ifdef __16C84
          bsf STATUS,RP0
          movwf TRISB&h'7f'
          bcf STATUS,RP0
          endif
          endm

option_   macro                    ; set options
          ifdef __16C54
          option
          endif
          ifdef __16C84
          bsf STATUS,RP0
          movwf OPTION_REG&h'7f'
          bcf STATUS,RP0
          endif
          endm


          org 0


;--------------------------------------------------------------------------
; reset vector
;--------------------------------------------------------------------------

          ifdef __16C84

          goto main_entry

          endif


;**************************************************************************
;                                                                         *
; Lookup tables                                                           *
;                                                                         *
;**************************************************************************

;--------------------------------------------------------------------------
; message addresses
;--------------------------------------------------------------------------

          table address_table

msg_      macro addr,mask,bit
          if addr&mask
          addr_ |= 1<<bit
          endif
          endm

msg       macro addr
          addr_ = 0
          msg_ addr,h'80',3
          msg_ addr,h'40',2
          msg_ addr,h'20',1
          msg_ addr,h'10',0
          msg_ addr,h'08',4
          msg_ addr,h'04',5
          msg_ addr,h'02',6
          msg_ addr,h'01',7
          entry addr_
          endm

          msg d'0'
          msg d'2'
          msg d'4'
          msg d'7'
          msg d'12'
          msg d'16'
          msg d'21'
          msg d'24'
          msg d'27'
          msg d'30'
          msg d'42'
          msg d'44'
          msg d'47'
          msg d'49'
          msg d'52'
          msg d'55'
          msg d'59'
          msg d'62'
          msg d'63'
          msg d'67'
          msg d'69'
          msg d'71'
          msg d'74'
          msg d'77'
          msg d'79'
          msg d'81'
          msg d'90'
          msg d'92'
          msg d'98'
          msg d'99'
          msg d'100'
          msg d'102'
          msg d'104'
          msg d'107'
          msg d'110'
          msg d'111'
          msg d'116'
          msg d'117'
          msg d'118'
          msg d'123'
          msg d'127'


;--------------------------------------------------------------------------
; jump table
;--------------------------------------------------------------------------

          table jump_table

          goto do_touch                 ; touch switch #4
          goto do_touch                 ; touch switch #3
          goto do_touch                 ; touch switch #2
          goto do_touch                 ; touch switch #1
          goto main_loop
          goto next_bank                ; bank button
          goto main_loop                ; faster button
          goto main_loop                ; slower button

          goto do_touch                 ; mode + touch switch #4
          goto do_touch                 ; mode + touch switch #3
          goto do_touch                 ; mode + touch switch #2
          goto do_touch                 ; mode + touch switch #1
          goto main_loop
          goto drum_mode                ; mode + drum buttons
          goto rhythm_mode              ; mode + rhythm buttons
          goto record_rhythm            ; mode + record buttons


;--------------------------------------------------------------------------
; rhythms
;--------------------------------------------------------------------------

; dddddsss = rhythm event:
;    ddddd = drum index, 1 to 31 (BEEP excluded)
;      sss = sustain - 1
; 00000000 = end of rhythm

          table rhythms_table

event     macro drum,sustain
          entry (drum<<3)+(sustain-1)
          endm

          event BASS2,d'2'              ; 8beat #4
          event CL_HIHAT,d'2'
          event SNARE1,d'2'
          event SNARE1,d'2'
          event BASS2,d'2'
          event CL_HIHAT,d'2'
          event SNARE1,d'2'
          event CL_HIHAT,d'2'
          entry 0

          event BASS2,d'2'              ; 8beat #3
          event BASS2,d'2'
          event SNARE1,d'2'
          event BASS2,d'2'
          event CL_HIHAT,d'2'
          event BASS2,d'2'
          event SNARE1,d'2'
          event CL_HIHAT,d'2'
          entry 0

          event BASS2,d'2'              ; 8beat #2
          event CL_HIHAT,d'2'
          event BASS2,d'2'
          event CL_HIHAT,d'2'
          event BASS2,d'2'
          event CL_HIHAT,d'2'
          event SNARE1,d'2'
          event CL_HIHAT,d'2'
          entry 0

          event BASS2,d'2'              ; 8beat #1
          event CL_HIHAT,d'2'
          event SNARE1,d'2'
          event CL_HIHAT,d'2'
          event BASS2,d'2'
          event BASS2,d'2'
          event SNARE1,d'2'
          event CL_HIHAT,d'2'
          entry 0


          event LO_AGOGO,d'1'           ; samba
          event LO_AGOGO,d'1'
          event LO_AGOGO,d'1'
          event CL_HIHAT,d'1'
          event HI_AGOGO,d'1'
          event HI_AGOGO,d'1'
          event HI_AGOGO,d'1'
          event CL_HIHAT,d'1'
          event LO_AGOGO,d'1'
          event LO_AGOGO,d'1'
          event CL_HIHAT,d'1'
          event HI_AGOGO,d'1'
          event CL_HIHAT,d'1'
          event HI_AGOGO,d'1'
          event HI_AGOGO,d'1'
          event CL_HIHAT,d'1'
          entry 0

          event BASS2,d'4'              ; reggae
          event BASS3,d'3'
          event BASS2,d'1'
          event CL_HIHAT,d'4'
          event BASS3,d'4'
          entry 0

          event SNARE1,d'1'             ; shuffle
          event SNARE1,d'2'
          event CL_HIHAT,d'1'
          event CL_HIHAT,d'2'
          event BASS2,d'1'
          event SNARE1,d'2'
          event BASS2,d'1'
          event CLAP,d'2'
          entry 0

          event CL_HIHAT,d'3'           ; jazz
          event OP_HIHAT,d'1'
          event OP_HIHAT,d'4'
          entry 0


          event BASS2,d'2'              ; pattern #1
          event CL_HIHAT,d'2'
          event SNARE1,d'2'
          event SNARE1,d'2'
          event BASS2,d'2'
          event SNARE1,d'1'
          event SNARE1,d'1'
          event SNARE1,d'1'
          event SNARE1,d'1'
          event SNARE1,d'2'
          entry 0

          event BASS2,d'1'              ; elec pop
          event BASS2,d'1'
          event BASS2,d'1'
          event BASS2,d'1'
          event CL_HIHAT,d'1'
          event CL_HIHAT,d'1'
          event BASS2,d'1'
          event BASS2,d'1'
          event BASS2,d'1'
          event BASS2,d'1'
          event BASS2,d'1'
          event BASS2,d'1'
          event CL_HIHAT,d'1'
          event CL_HIHAT,d'1'
          event CL_HIHAT,d'1'
          event CL_HIHAT,d'1'
          entry 0

          event OP_HIHAT,d'2'           ; disco #2
          event SNARE1,d'2'
          event OP_HIHAT,d'2'
          event BASS2,d'2'
          entry 0

          event CL_HIHAT,d'1'           ; disco #1
          event CL_HIHAT,d'1'
          event SNARE1,d'2'
          event CL_HIHAT,d'1'
          event CL_HIHAT,d'1'
          event BASS2,d'2'
          entry 0


;**************************************************************************
;                                                                         *
; Procedures                                                              *
;                                                                         *
;**************************************************************************

;--------------------------------------------------------------------------
; polls the push buttons and touch switches
;--------------------------------------------------------------------------

          routine poll_buttons

          clrf buttons

          btfss TMR0,7                  ; within debounce period ?
          goto poll1                    ; branch if yes

          clrf TMR0

          movlw PORTB_IN                ; input mode
          tris_B

          movff buttons_,buttons

          movlw b'11111111'             ; poll the buttons
          movwf BUTTONS_PORT
          clrwdt
          swapf BUTTONS_PORT,w
          xorlw h'f0'
          movwf buttons_

          bcf flags,SHIFT               ; get the shift state
          btfsc buttons_,MODE
          bsf flags,SHIFT
          bcf buttons_,MODE

          comf buttons,w
          andwf buttons_,w
          movwf buttons

poll1     retlw 0


;--------------------------------------------------------------------------
; runs the tempo timer
;--------------------------------------------------------------------------

          routine do_timer

          clrwdt                        ; clear watchdog timer [4]

          movfw TMR0                    ; clock rolled over ? [4]
          andlw TIMER_MASK              ; [4]
          bnz time1                     ; branch if not [12]

          btfss flags,TMR               ; timer flag set ?
          incf timer                    ; increment timer if not

          bsf flags,TMR                 ; set timer flag

          goto time2

time1     bcf flags,TMR                 ; clear timer flag [4]

time2     retlw 0                       ; [8]


;--------------------------------------------------------------------------
; increases the tempo
;--------------------------------------------------------------------------

inc_tempo      macro

          movlw TEMPO_MAX
          subwf tempo,w
          skpz
          decf tempo

          endm


;--------------------------------------------------------------------------
; decreases the tempo
;--------------------------------------------------------------------------

dec_tempo      macro

          movlw TEMPO_MIN
          subwf tempo,w
          skpz
          incf tempo

          endm


;--------------------------------------------------------------------------
; steps to the next drum or rhythm bank
;--------------------------------------------------------------------------

          routine next_bank

          call beep

          btfss flags,MODE_RHYTHM       ; rhythm mode ?
          goto next1                    ; branch if not

          swapf banks                   ; next rhythm bank
          incf banks

          movlw RHYTHM_BANKS            ; wrap around
          subwf banks,w
          movlw h'f0'
          skpndc
          andwf banks

          swapf banks

          goto next2

next1     incf banks                    ; next drum bank

          movlw DRUM_BANKS              ; wrap around
          subwf banks,w
          movlw h'f0'
          skpndc
          andwf banks

next2     btfsc flags,MODE_RECORD
          goto record_loop
          goto main_loop


;--------------------------------------------------------------------------
; button pressed
;--------------------------------------------------------------------------

          routine do_button

          movfw buttons                 ; button pressed ?
          bz dob2                       ; branch if not

          movwf work                    ; determine the button
          movlf 8,count                 ; pressed
dob1      decf count
          rlf work
          bnc dob1
          btfsc flags,SHIFT
          bsf count,3
          movfw count

          goto jump_table

dob2      retlw 0


;--------------------------------------------------------------------------
; beeps
;--------------------------------------------------------------------------

          routine beep

          clrf sustain
          movlw BEEP
;         goto play_drum


;--------------------------------------------------------------------------
; plays a drum, fed with the drum index in w (0 onwards, -ve if silence)
;--------------------------------------------------------------------------

          routine play_drum

          movwf count                   ; save index

          btfsc count,7                 ; silence ?
          goto playd1                   ; branch if yes

          movlw PORTB_OUT               ; output mode
          tris_B

          movfw count                   ; get the message address
          index address_table           
          movwf ADDR_PORT
          nop

          bcf PLAYL                     ; play message

          movlw PORTB_IN                ; input mode
          tris_B

playd1    clrf timer                    ; initialise tempo timer

playd2    call do_timer                 ; run tempo timer

          call poll_buttons             ; poll the buttons

          btfsc flags,SHIFT
          goto playd4

          btfss buttons,FAST            ; tempo button pressed ?
          goto playd3                   ; branch if not

          inc_tempo                     ; increment tempo

          bcf buttons,FAST

playd3    btfss buttons,SLOW            ; tempo button pressed ?
          goto playd4                   ; branch if not

          dec_tempo                     ; decrement tempo

          bcf buttons,SLOW

playd4    tstf buttons                  ; button pressed ?
          bnz playd7                    ; branch if yes

          tstf sustain                  ; sustain specified ?
          bz playd5                     ; play to end if not

          movfw timer                   ; tempo timeout ?
          subwf tempo,w
          bc playd2                     ; branch if not

          bcf LED                       ; LED off

          decfsz sustain                ; end of sustain ?
          goto playd1                   ; loop if not

          goto playd7

playd5    bsf RECLED                    ; wait for EOM rising edge
          clrwdt
          btfsc RECLED
          goto playd2

playd6    bsf RECLED
          clrwdt
          btfss RECLED
          goto playd6

playd7    bsf PLAYL                     ; stop message

WAIT      set  (CLOCK*DEBOUNCE)/(d'1000'*d'56'*d'256')

          movlf WAIT,count              ; wait for ISD debounce period
playd8    clrf work
playd9    call do_timer                 ; [8+36]
          decfsz work                   ; [4]
          goto playd9                   ; [8]
          decfsz count
          goto playd8

          bsf TMR0,7

          bcf LED                       ; LED off

          retlw 0


;--------------------------------------------------------------------------
; touch switch pressed
;--------------------------------------------------------------------------

          routine do_touch

          bcf count,3

          btfss flags,MODE_RHYTHM       ; rhythm mode ?
          goto dot1                     ; branch if not

          rrf banks,w                   ; get rhythm index
          movwf work
          rrf work,w
          andlw b'1111'<<2              ; current bank * 4
          addwf count,w

          goto play_rhythm              ; play rhythm

dot1      rlf banks,w                   ; get drum index
          movwf work
          rlf work,w
          andlw b'1111'<<2              ; current bank * 4
          iorlw 1
          addwf count,w
          movwf count

          btfsc flags,MODE_RECORD       ; record mode ?
          goto record_add               ; branch if yes

          bsf flags,MODE_DRUM           ; drum mode

          clrf sustain                  ; play drum
          call play_drum

          call do_button

          goto main_loop


;--------------------------------------------------------------------------
; plays a rhythm, fed with the rhythm index in w (0 onwards)
;--------------------------------------------------------------------------

          routine play_rhythm

          movwf count                   ; find the rhythm

          clrf rhythm_start

playr1    tstf count
          bz playr3

playr2    movfw rhythm_start            ; step over rhythm
          index rhythms_table
          incf rhythm_start
          tstw
          bnz playr2

          decf count
          goto playr1

playr3    movff rhythm_start,rhythm_pnt

          bsf LED                       ; flash LED at start of loop

playr4    movfw rhythm_pnt              ; get the next rhythm event
          index rhythms_table
          incf rhythm_pnt
          movwf work

          tstw                          ; end of rhythm ?
          bz playr3                     ; repeat if yes

          andlw h'07'                   ; get the sustain (1 to 8)
          movwf sustain
          incf sustain

          swapf work                    ; get the drum index
          rlf work,w
          rlf work,w
          andlw h'1f'

          call play_drum                ; play the drum

          call do_button

          goto playr4                   ; loop


;--------------------------------------------------------------------------
; records a rhythm
;--------------------------------------------------------------------------

          routine record_rhythm

          call beep

          btfss flags,MODE_RECORD       ; record mode ?
          goto recr1                    ; branch if not

          bcf flags,MODE_RECORD         ; stop record mode

          goto record_loop

recr1     movlw (0<<4)+(d'16'-1)        ; initialise the user rhythm
          movwf buffer+0                ; buffer
          movwf buffer+1
          movwf buffer+2                ; 4 beats with metronome click
          movwf buffer+3                ; on each beat

          movlf buffer+4,FSR            ; pad remainder of buffer
          movlw -1                      ; with illegal rhythm event
recr2     movwf 0
          ifdef __16C54
          incfsz FSR
          endif
          ifdef __16C84
          incf FSR
          btfss FSR,5
          endif
          goto recr2

          bcf flags,MODE_DRUM           ; signal record mode
          bcf flags,MODE_RHYTHM
          bsf flags,MODE_RECORD

          movlf buffer,FSR              ; play the user rhythm


          routine record_loop

          bcf banks,2                   ; drum bank #1 to #4
          bcf banks,3

rloop1    movff FSR,rhythm_pnt          ; save pointer

          movff 0,work                  ; get the next rhythm event

rloop2    incf FSR                      ; step rhythm pointer
          movlw buffer
          ifdef __16C54
          skpnz
          endif
          ifdef __16C84
          btfsc FSR,5
          endif
          movwf FSR                     ; wrap around

          incf work,w                   ; pad event ?
          bz rloop1                     ; ignore if yes

          incf 0,w                      ; pad event ?
          bz rloop2                     ; ignore if yes

          movfw work                    ; get the sustain
          andlw h'0f'
          bcf flags,SHORT
          skpnz
          bsf flags,SHORT               ; flag minimum sustain
          movwf sustain
          incf sustain                  ; 1 to 16

          btfsc flags,MODE_RECORD       ; record mode ?
          goto rloop3                   ; branch if yes

          swapf work,w                  ; ignore metronome clicks
          andlw h'0f'
          movlw -1
          bz rloop4

          swapf 0,w                     ; followed by metronome click ?
          andlw h'0f'
          bnz rloop3                    ; branch if not

          movfw 0                       ; add the sustain
          andlw h'0f'
          addwf sustain
          incf sustain

          incf FSR                      ; step over the click
          movlw buffer
          ifdef __16C54
          skpnz
          endif
          ifdef __16C84
          btfsc FSR,5
          endif
          movwf FSR

rloop3    swapf work,w                  ; get the drum index
          andlw h'0f'
          bnz rloop4                    ; branch if not metronome

          bsf LED                       ; flash LED and sound click
          movlw CLICK

rloop4    call play_drum                ; play the drum

          call do_button

          goto record_loop


          routine record_add

          incf buffer_end,w             ; user buffer full ?
          bnz radd3                     ; branch if yes

          btfsc flags,SHORT             ; minimum sustain ?
          goto radd3                    ; branch if yes

          movlf buffer_end,FSR          ; make space in the buffer

radd1     decf FSR
          movfw FSR
          subwf rhythm_pnt,w
          bz radd2

          movfw 0
          incf FSR
          movwf 0
          decf FSR

          goto radd1

radd2     decf sustain                  ; modify sustain of current
          skpnz                         ; event
          incf sustain
          movfw sustain
          subwf 0

          incf FSR

          movfw count                   ; drum index
          andlw h'0f'

          movwf 0                       ; add event to user rhythm
          swapf 0
          decf sustain,w
          addwf 0

radd3     retlw 0


;--------------------------------------------------------------------------
; main entry point
;--------------------------------------------------------------------------

          routine main_entry

          movlw PORTA_IO                ; initialise ports
          tris_A
          movlw PORTB_IN
          tris_B

          bsf PLAYL                     ; inactive
          bsf PLAYE

          clrwdt                        ; clear watchdog timer

          ifdef __16C84                 ; disable weak pull-ups
          bsf STATUS,RP0
          bsf OPTION_REG&h'7f',7
          bcf STATUS,RP0
          endif

          movlf RAM,FSR                 ; clear memory
main1     clrf 0
          ifdef __16C54
          incfsz FSR
          endif
          ifdef __16C84
          incf FSR
          btfss FSR,5
          endif
          goto main1

main2     clrwdt                        ; power up delay
          decfsz work
          goto main2
          decfsz count
          goto main2

          clrf banks                    ; rhythm & drum banks #1

          movlf TEMPO_INIT,tempo        ; initial tempo

          call poll_buttons             ; initial poll

          bsf LED                       ; test LED

          clrf TMR0


;--------------------------------------------------------------------------
; drum mode
;--------------------------------------------------------------------------

          routine drum_mode

          bsf flags,MODE_DRUM           ; signal drum mode
          bcf flags,MODE_RHYTHM
          goto mode1


;--------------------------------------------------------------------------
; rhythm mode
;--------------------------------------------------------------------------

          routine rhythm_mode

          bcf flags,MODE_DRUM           ; signal rhythm mode
          bsf flags,MODE_RHYTHM
mode1     bcf flags,MODE_RECORD

          call beep


;--------------------------------------------------------------------------
; main loop
;--------------------------------------------------------------------------

          routine main_loop

          movlw PORTA_IO                ; re-initialise ports
          tris_A
          movlw PORTB_IN
          tris_B

          bsf PLAYL                     ; inactive
          bsf PLAYE

          ifdef __16C54                 ; prescale RTCC 1:128
          movlw b'000110'
          endif
          ifdef __16C84
          movlw b'10000110'
          endif
          option_

          clrwdt                        ; clear watchdog timer

          bcf LED                       ; LED off

          call poll_buttons             ; poll the buttons

          call do_button

          goto main_loop


;--------------------------------------------------------------------------
; reset vector
;--------------------------------------------------------------------------

          ifdef __16C54

          org h'1ff'

          goto main_entry

          endif


          end