;**************************************************************************
; FILE:      lotto.asm                                                    *
; CONTENTS:  'Lottomania'                                                 *
; COPYRIGHT: MadLab Ltd. 1995                                             *
; AUTHOR:    James Hutchby                                                *
; UPDATED:   06/10/99                                                     *
;**************************************************************************

;    list p=16C54A
     list p=16C54C

     include "p16c5x.inc"

     __config _RC_OSC & _WDT_ON & _CP_ON

     __idlocs h'AD11'

     errorlevel -305


;**************************************************************************
;                                                                         *
; Specification                                                           *
;                                                                         *
;**************************************************************************

; National Lottery mode :-
;   RESET/MODE button clears
;   NEXT button generates a random number from 1 to 49
;   subsequently generates a random number from 1 to 48
;   and so on until 6 numbers have been generated

; single die mode :-
;   RESET/MODE button clears
;   NEXT button generates a random number from 1 to 6

; double dice mode :-
;   RESET/MODE button clears
;   NEXT button generates a pair of random numbers from 1 to 6

; heads or tails mode :-
;   RESET/MODE button clears
;   NEXT button generates a random heads or tails

; 1-player reaction timer mode :-
;   RESET/MODE button clears
;   NEXT button starts count after random time interval
;     NEXT button stops count and displays reaction time
;     count stops at 99 and flashes

; 2-player reaction tester mode :-
;   RESET/MODE button clears
;   NEXT button displays 'XX' after random time interval
;     RESET/MODE button displays '1 '
;     NEXT button displays ' 2'

; tracker game mode :-
;   NEXT button displays '55'
;     high digit counts up and down at random
;     RESET/MODE button counts low digit down
;     NEXT button counts low digit up
;     digits wrap around 0 to 9
;     if absolute difference between high and low digits is greater
;     than 3 then stops counting and flashes digits
;     high digit counts progressively faster

; RESET/MODE button held down for ~2 seconds -> mode select
;   button held down -> mode cycles


;**************************************************************************
;                                                                         *
; Port assignments                                                        *
;                                                                         *
;**************************************************************************

PORTA_IO       equ  b'1100'        ; port A I/O status
PORTB_IO       equ  b'00000000'    ; port B I/O status

LEDS      equ  PORTB               ; 7-segment LEDs

#define   ENABLE_HI PORTA,0        ; high character enable
#define   ENABLE_LO PORTA,1        ; low character enable

BUTTONS   equ  PORTA               ; buttons
BUTTON1   equ  2                   ; button1 (RESET/MODE)
BUTTON2   equ  3                   ; button2 (NEXT)

CA        equ  0                   ; set if common anode 7-segment
CC        equ  1                   ; set if common cathode 7-segment


;**************************************************************************
;                                                                         *
; Constants and timings                                                   *
;                                                                         *
;**************************************************************************

CLOCK     equ  d'2000000'          ; processor clock frequency in Hz

DELAY_PERIOD        equ  d'120'    ; button poll period (~1/16 s)
REACT_PERIOD        equ  d'12'     ; reaction timer poll period
DISPLAY_PERIOD      equ  d'10'     ; display multiplex period
PATTERN_PERIOD      equ  d'40'     ; pattern cycle period
SELECT_PERIOD       equ  d'35'     ; mode select period
CYCLE_PERIOD        equ  d'15'     ; mode cycle period

MIN_REACT      equ  d'8'           ; minimum reaction wait time
MAX_REACT      equ  d'60'          ; maximum reaction wait time

MIN_TRACK      equ  d'22'          ; minimum tracker speed
MAX_TRACK      equ  d'4'           ; maximum tracker speed
TRACK_STEP     equ  d'100'         ; tracker step speed
TRACK_INC      equ  d'5'           ; step speed increment

NMODES         equ  d'7'           ; number of modes

NBALLS         equ  d'49'          ; total number of balls
NSELECT        equ  d'6'           ; number of balls to select

NBYTES    equ  (NBALLS+d'7')/d'8'
REACT     equ  MAX_REACT-MIN_REACT


;**************************************************************************
;                                                                         *
; File register usage                                                     *
;                                                                         *
;**************************************************************************

     cblock h'07'
     flags                    ; various flags
     work1, work2             ; work registers
     char                     ; character to display (0 = high, h'ff' = low)
     char_hi, char_lo         ; high and low characters
     save_hi, save_lo         ; saved characters
     timer                    ; timer
     range                    ; random number range
     random                   ; random number selection
     react:0                  ; reaction time

     track, track_            ; tracker speed
     step, step_              ; step speed

     mode                     ; mode :-
                              ; 0 = National Lottery ('49')
                              ; 1 = single die (' 6')
                              ; 2 = double dice ('66')
                              ; 3 = heads or tails ('ht')
                              ; 4 = 1-player reaction timer ('G1')
                              ; 5 = 2-player reaction tester ('G2')
                              ; 6 = tracker game ('G3')

     ball                     ; ball index
     mask                     ; ball flags mask
     used:NBYTES              ; ball used flags
     endc

; flags
RELEASE   equ  0              ; set if waiting for release
FLASH     equ  1              ; set if display to be flashed


;**************************************************************************
;                                                                         *
; Macros                                                                  *
;                                                                         *
;**************************************************************************

routine   macro label              ; routine
label
          endm

table     macro label              ; define lookup table
label     addwf PCL
          endm

entry     macro value              ; define table entry
          retlw value
          endm

index     macro label              ; index lookup table
          call label
          endm

jump      macro label              ; jump through table
          goto label
          endm

tstw      macro                    ; test w register
          iorlw 0
          endm

movff     macro f1,f2              ; move file to file
          movfw f1
          movwf f2
          endm

movlf     macro n,f                ; move literal to file
          movlw n
          movwf f
          endm


          org 0


;**************************************************************************
;                                                                         *
; lookup tables                                                           *
;                                                                         *
;**************************************************************************

SPC            equ  d'10'
DASH           equ  d'11'
HEADS          equ  d'12'
TAILS          equ  d'13'
GAME           equ  d'14'
BARS           equ  d'15'
PATTERN_LO     equ  d'16'
PATTERN_HI     equ  d'21'

; A = 2, B = 3, C = 6, D = 5, E = 4, F = 0, G = 1, DP = 7

          table LEDS_hi            ; high 7-segment LEDs

          entry b'01111101'        ; ABCDEF. = '0'
          entry b'01001000'        ; .BC.... = '1'
          entry b'00111110'        ; AB.DE.G = '2'
          entry b'01101110'        ; ABCD..G = '3'
          entry b'01001011'        ; .BC..FG = '4'
          entry b'01100111'        ; A.CD.FG = '5'
          entry b'01110011'        ; ..CDEFG = '6'
          entry b'01001100'        ; ABC.... = '7'
          entry b'01111111'        ; ABCDEFG = '8'
          entry b'01001111'        ; ABC..FG = '9'

          entry b'00000000'        ; ....... = ' '
          entry b'00000010'        ; ......G = '-'
          entry b'01010011'        ; ..C.EFG = 'h'
          entry b'00110011'        ; ...DEFG = 't'
          entry b'01110101'        ; A.CDEF. = 'G'

          entry b'00001111'        ; AB...FG

          entry b'00001100'        ; AB.....
          entry b'01001000'        ; .BC....
          entry b'01100000'        ; ..CD...
          entry b'00110000'        ; ...DE..
          entry b'00010001'        ; ....EF.
          entry b'00000101'        ; A....F.


; A = 2, B = 1, C = 5, D = 7, E = 0, F = 3, G = 6, DP = 4

          table LEDS_lo            ; low 7-segment LEDs

          entry b'10101111'        ; ABCDEF. = '0'
          entry b'00100010'        ; .BC.... = '1'
          entry b'11000111'        ; AB.DE.G = '2'
          entry b'11100110'        ; ABCD..G = '3'
          entry b'01101010'        ; .BC..FG = '4'
          entry b'11101100'        ; A.CD.FG = '5'
          entry b'11101001'        ; ..CDEFG = '6'
          entry b'00100110'        ; ABC.... = '7'
          entry b'11101111'        ; ABCDEFG = '8'
          entry b'01101110'        ; ABC..FG = '9'

          entry b'00000000'        ; ....... = ' '
          entry b'01000000'        ; ......G = '-'
          entry b'01101001'        ; ..C.EFG = 'h'
          entry b'11001001'        ; ...DEFG = 't'
          entry b'10101101'        ; A.CDEF. = 'G'

          entry b'11100001'        ; ..CDE.G

          entry b'00000110'        ; AB.....
          entry b'00100010'        ; .BC....
          entry b'10100000'        ; ..CD...
          entry b'10000001'        ; ...DE..
          entry b'00001001'        ; ....EF.
          entry b'00001100'        ; A....F.


          table mode_hi            ; mode display high character

          entry d'4'               ; National Lottery
          entry SPC                ; single die
          entry d'6'               ; double dice
          entry HEADS              ; heads or tails
          entry GAME               ; reaction timer
          entry GAME               ; reaction tester
          entry GAME               ; tracker game

          table mode_lo            ; mode display low character

          entry d'9'               ; National Lottery
          entry d'6'               ; single die
          entry d'6'               ; double dice
          entry TAILS              ; heads or tails
          entry d'1'               ; reaction timer
          entry d'2'               ; reaction tester
          entry d'3'               ; tracker game


          table range_table        ; random number range

          entry NBALLS             ; National Lottery
          entry d'6'               ; single die
          entry d'6'*d'6'          ; double dice
          entry d'2'               ; heads or tails
          entry REACT              ; reaction timer
          entry REACT              ; reaction tester
          entry d'2'               ; tracker game


          table base_table         ; number base

          entry d'10'              ; National Lottery
          entry d'6'               ; single die
          entry d'6'               ; double dice
          entry d'2'               ; heads or tails
          entry d'10'              ; reaction timer


          table mode_jump          ; mode jump table

          goto mode0
          goto mode1
          goto mode2
          goto mode3
          goto mode4
          goto mode5
          goto mode6


;**************************************************************************
;                                                                         *
; Procedures                                                              *
;                                                                         *
;**************************************************************************

;--------------------------------------------------------------------------
; tests the reset/mode button
;--------------------------------------------------------------------------

          routine test_reset

          movlw 1<<BUTTON1
          iorwf BUTTONS
          nop
          andwf BUTTONS,w

          retlw 0                       ; Z flag set if button pressed


;--------------------------------------------------------------------------
; tests the next button
;--------------------------------------------------------------------------

          routine test_next

          movlw 1<<BUTTON2
          iorwf BUTTONS
          nop
          andwf BUTTONS,w

          retlw 0                       ; Z flag set if button pressed


;--------------------------------------------------------------------------
; tests both buttons
;--------------------------------------------------------------------------

test_buttons   macro

          call test_reset
          skpz
          call test_next

          endm


;--------------------------------------------------------------------------
; displays a single character
;--------------------------------------------------------------------------

display_char   macro

          local dispd1,dispd2

          comf char                     ; high character ?
          bz dispd1                     ; branch if not

          if CA                         ; display high character
          bcf ENABLE_LO
          endif
          if CC
          bsf ENABLE_LO
          endif
          movfw char_hi
          index LEDS_hi
          if CA
          xorlw h'ff'
          endif
          movwf LEDS
          if CA
          bsf ENABLE_HI
          endif
          if CC
          bcf ENABLE_HI
          endif

          goto dispd2

dispd1
          if CA                         ; display low character
          bcf ENABLE_HI
          endif
          if CC
          bsf ENABLE_HI
          endif
          movfw char_lo
          index LEDS_lo
          if CA
          xorlw h'ff'
          endif
          movwf LEDS
          if CA
          bsf ENABLE_LO
          endif
          if CC
          bcf ENABLE_LO
          endif

dispd2
          endm


;--------------------------------------------------------------------------
; poll delay
;--------------------------------------------------------------------------

          routine poll_delay

          movlw DELAY_PERIOD


          routine delay

          movwf work1

delay1    movlf DISPLAY_PERIOD,work2

delay2    clrwdt

          test_buttons                  ; button pressed ?
          bnz delay3                    ; branch if not

          incf random                   ; next random number
          movfw random
          subwf range,w
          skpnz
          clrf random

delay3    decfsz work2
          goto delay2

          display_char                  ; multiplex the display

          decfsz work1
          goto delay1

          retlw 0


;--------------------------------------------------------------------------
; converts a number to decimal digits
;--------------------------------------------------------------------------

          routine get_digits

          movwf char_lo

          movfw mode                    ; determine base
          index base_table

          clrf char_hi
getd1     subwf char_lo
          bnc getd2
          incf char_hi
          goto getd1
getd2     addwf char_lo

          decf mode,w                   ; die adjustment
          andlw h'fe'
          bnz getd3
          incf char_lo
          btfss mode,0
          incf char_hi

getd3     tstf char_hi                  ; suppress leading zero
          movlw SPC
          skpnz
          movwf char_hi

          retlw 0


;--------------------------------------------------------------------------
; blanks display
;--------------------------------------------------------------------------

          routine blank

          movfw mode                    ; display '--' or ' -'
          andlw b'101'
          xorlw b'001'
          movlw DASH
          movwf char_lo
          skpnz
          movlw SPC
          movwf char_hi

          retlw 0


;--------------------------------------------------------------------------
; buttons executive
;--------------------------------------------------------------------------

          routine buttons_exec

          call test_reset               ; reset/mode button pressed ?
          bz reset_pressed              ; branch if yes

          tstf mode                     ; National Lottery mode ?
          bnz exec1                     ; branch if not

          movlw NBALLS-NSELECT          ; finished ?
          subwf range,w
          bz exec2                      ; branch if yes

exec1     call test_next                ; next button pressed ?
          bz next_pressed               ; branch if yes

exec2     retlw 0


;--------------------------------------------------------------------------
; main entry point
;--------------------------------------------------------------------------

          routine main_entry

          clrf PORTA                    ; initialise ports
          movlw PORTA_IO
          tris PORTA
          clrf PORTB
          movlw PORTB_IO
          tris PORTB

          movfw STATUS                  ; wake-up from sleep ?
          andlw (1<<NOT_TO)+(1<<NOT_PD)
          clrwdt
          bz main1                      ; branch if yes

          clrf char

          clrf mode                     ; mode 0

          goto clear

main1     call buttons_exec

;         goto sleep_mode


;--------------------------------------------------------------------------
; sleep mode
;--------------------------------------------------------------------------

          routine sleep_mode

          clrf PORTA                    ; LEDs off

          movlw b'001010'               ; prescale WDT 1:4
          option

          clrwdt

          sleep                         ; standby mode


;--------------------------------------------------------------------------
; mode select
;--------------------------------------------------------------------------

          routine select

          movlf CYCLE_PERIOD,timer      ; initialise timer

select1   movfw mode                    ; display mode indicator
          index mode_hi
          movwf char_hi
          movfw mode
          index mode_lo
          movwf char_lo

          call poll_delay

          call test_reset               ; reset/mode button released ?
          bnz clear                     ; branch if yes

          decfsz timer
          goto select1

          incf mode                     ; next mode
          movlw NMODES
          subwf mode,w
          skpnz
          clrf mode

          goto select                   ; loop


;--------------------------------------------------------------------------
; reset/mode button pressed
;--------------------------------------------------------------------------

          routine reset_pressed

          call blank                    ; display '--' or ' -'

          movlf SELECT_PERIOD,timer     ; initialise timer

reset1    call poll_delay

          call test_reset               ; button released ?
          bnz clear                     ; branch if yes

          decfsz timer
          goto reset1

          goto select                   ; mode select if timeout


;--------------------------------------------------------------------------
; clears mode
;--------------------------------------------------------------------------

          routine clear

          movfw mode                    ; random number range
          index range_table
          movwf range

          movlf used,FSR                ; clear the ball used flags
clear1    clrf 0
          incfsz FSR
          goto clear1

          call blank                    ; display '--' or ' -'

          goto main_loop


;--------------------------------------------------------------------------
; next button pressed
;--------------------------------------------------------------------------

          routine next_pressed

          clrf random

          movlw SPC
          movwf char_lo
          movwf char_hi

          movlw d'4'                    ; random number mode ?
          subwf mode,w
          bc next2                      ; branch if not

          movlf PATTERN_LO,char_lo      ; display pattern

next1     movfw char_lo
          btfss mode,0
          movwf char_hi

next2     movlw PATTERN_PERIOD
          call delay

          call test_next                ; button released ?
          bnz next3                     ; branch if yes

          movlw d'4'                    ; random number mode ?
          subwf mode,w
          bc next2                      ; branch if not

          incf char_lo                  ; cycle pattern
          movlw PATTERN_HI+1
          subwf char_lo,w
          movlw PATTERN_LO
          skpnz
          movwf char_lo

          goto next1

next3     movfw mode
          goto mode_jump


;--------------------------------------------------------------------------
; waits for reset button to be pressed
;--------------------------------------------------------------------------

          routine wait_reset

          movff char_lo,save_lo
          movff char_hi,save_hi

          clrf timer                    ; reset timer

wait1     movff save_lo,char_lo
          movff save_hi,char_hi

          btfss flags,FLASH
          goto wait2

          btfss timer,2                 ; flash display
          goto wait2
          movlw SPC
          movwf char_lo
          movwf char_hi

wait2     call poll_delay

          incf timer

          btfsc flags,RELEASE
          goto wait3

          call test_reset               ; reset/mode button pressed ?
          bz reset_pressed              ; branch if yes

          tstf timer                    ; timeout ?
          bz clear                      ; branch if yes

          goto wait1

wait3     test_buttons                  ; wait for buttons to be
          skpz                          ; released
          bcf flags,RELEASE

          goto wait1


;--------------------------------------------------------------------------
; National Lottery
;--------------------------------------------------------------------------

          routine mode0

          clrf ball                     ; ball index

m01       rrf ball,w
          movwf work1
          rrf work1
          rrf work1,w
          andlw h'1f'                   ; byte offset
          movwf FSR
          movlw used
          addwf FSR                     ; pointer to flag byte

          movfw ball
          andlw h'07'
          movwf work1                   ; bit number

          clrf mask                     ; get a bit mask
          incf work1
          setc
m02       rrf mask
          decfsz work1
          goto m02

          movfw mask                    ; ball used ?
          andwf 0,w
          bnz m03                       ; branch if yes

          tstf random
          bz m04
          decf random

m03       incf ball
          goto m01

m04       movfw mask                    ; set the used flag
          iorwf 0

          incf ball,w                   ; convert to decimal digits
          call get_digits

          decf range                    ; decrement balls left

          goto main_loop


;--------------------------------------------------------------------------
; single die or double dice
;--------------------------------------------------------------------------

          routine mode1
          routine mode2

          movfw random                  ; convert to decimal digits
          call get_digits

          goto main_loop


;--------------------------------------------------------------------------
; heads or tails
;--------------------------------------------------------------------------

          routine mode3

          movlf SPC,char_hi             ; display ' h' or ' t'
          movlw HEADS
          btfsc random,0
          movlw TAILS
          movwf char_lo

          goto main_loop


;--------------------------------------------------------------------------
; reaction timer
;--------------------------------------------------------------------------

          routine mode4

          movlw MIN_REACT               ; reaction wait time
          addwf random

m41       call poll_delay

          call test_reset               ; reset/mode button pressed ?
          bz reset_pressed              ; branch if yes

          movlf d'99',react             ; player loses if button
          call test_next                ; pressed too early
          bz m43

          decfsz random
          goto m41

          clrf react

m42       incf react                    ; increment reaction time

m43       movfw react                   ; display reaction time
          call get_digits

          movlw REACT_PERIOD
          call delay

          movlw d'99'                   ; overflow ?
          subwf react,w
          bcf flags,RELEASE
          bsf flags,FLASH
          bz wait_reset                 ; branch if yes

          call test_reset               ; reset/mode button pressed ?
          bz reset_pressed              ; branch if yes

          call test_next                ; next button pressed ?
          bcf flags,RELEASE
          bcf flags,FLASH
          bz wait_reset                 ; branch if yes

          goto m42                      ; loop


;--------------------------------------------------------------------------
; reaction tester
;--------------------------------------------------------------------------

          routine mode5

          movlw MIN_REACT               ; reaction wait time
          addwf random

m51       call poll_delay

          call test_reset               ; player loses if button
          bz m53                        ; pressed too early
          call test_next
          bz m54

          decfsz random
          goto m51

m52       movlw BARS                    ; display bars
          movwf char_lo
          movwf char_hi

          movlw 1
          call delay

          call test_reset               ; button pressed ?
          bz m54
          call test_next
          bnz m52                       ; loop if not

m53       movlf SPC,char_hi             ; player #2 won
          movlf 2,char_lo
          goto m55

m54       movlf 1,char_hi               ; player #1 won
          movlf SPC,char_lo

m55       bsf flags,RELEASE
          bcf flags,FLASH
          goto wait_reset


;--------------------------------------------------------------------------
; tracker game
;--------------------------------------------------------------------------

          routine mode6

wrap10    macro reg

          movlw d'9'                    ; wrap around 0 to 9
          btfsc reg,7
          movwf reg
          movlw d'10'
          subwf reg,w
          skpnz
          clrf reg

          endm

          movlw d'5'                    ; display '55'
          movwf char_hi
          movwf char_lo

          movlw MIN_TRACK               ; initial tracker speed
          movwf track
          movwf track_

          movlw TRACK_STEP              ; initial step speed
          movwf step
          movwf step_

          movlf SELECT_PERIOD,timer     ; initialise timer

          bsf flags,RELEASE             ; signal waiting for release

m61       call poll_delay

          btfss flags,RELEASE
          goto m62

          call test_reset               ; mode select if reset/mode
          skpnz                         ; button held down
          decf timer
          tstf timer
          bz select

          test_buttons
          skpz
          bcf flags,RELEASE

          goto m65

m62       call test_reset               ; count low digit up or down
          bz m63                        ; if button pressed
          call test_next
          bnz m65
          incf char_lo
          goto m64
m63       decf char_lo

m64       wrap10 char_lo                ; wrap around

          movlf SELECT_PERIOD,timer     ; initialise timer

          bsf flags,RELEASE             ; signal waiting for release

m65       decfsz track_
          goto m66
          movff track,track_

          btfsc random,0                ; count high digit up or down
          incf char_hi                  ; at random
          btfss random,0
          decf char_hi

          wrap10 char_hi                ; wrap around

m66       decfsz step_
          goto m67
          movff step,step_

          movlw MAX_TRACK               ; increase tracker speed
          subwf track,w
          bz m67
          decf track

          movlw TRACK_INC
          addwf step

m67       clrf work1                    ; determine the absolute
          movfw char_hi                 ; difference between the
          subwf char_lo,w               ; digits
          skpc
          subwf work1,w
          movwf work1

          movlw d'4'                    ; tracking close enough ?
          subwf work1
          movlw d'3'
          subwf work1
          bc m61                        ; loop if yes

          bsf flags,RELEASE             ; flash digits
          bsf flags,FLASH
          goto wait_reset


;--------------------------------------------------------------------------
; main loop
;--------------------------------------------------------------------------

          routine main_loop

          clrf timer                    ; reset timer

loop0     movlw PORTA_IO                ; re-initialise ports
          tris PORTA
          movlw PORTB_IO
          tris PORTB

          incf timer                    ; timeout ?
          bz sleep_mode                 ; branch if yes

          call poll_delay

          call buttons_exec

          goto loop0                    ; loop


;--------------------------------------------------------------------------
; reset vector
;--------------------------------------------------------------------------

          org h'1ff'

          goto main_entry


          end