;**************************************************************************
; FILE:      mice.asm                                                     *
; CONTENTS:  "You've got mice"                                            *
; COPYRIGHT: MadLab Ltd. 2003                                             *
; AUTHOR:    James Hutchby                                                *
; UPDATED:   07/04/03                                                     *
;**************************************************************************

;    list p=12F629
     list p=12C508A

     ifdef __12F629
     #include "p12f629.inc"
     endif
     ifdef __12C508A
     #include "p12c508a.inc"
     endif

     ifdef __12F629
     __config _INTRC_OSC_NOCLKOUT & _WDT_ON & _MCLRE_OFF & _PWRTE_ON & _BODEN_ON & _CP_OFF & _CPD_OFF
;    __config _INTRC_OSC_NOCLKOUT & _WDT_ON & _MCLRE_OFF & _PWRTE_ON & _BODEN_ON & _CP_ON & _CPD_ON
     endif
     ifdef __12C508A
;    __config _IntRC_OSC & _WDT_ON & _MCLRE_OFF & _CP_OFF
     __config _IntRC_OSC & _WDT_ON & _MCLRE_OFF & _CP_ON
     endif

     __idlocs h'DD10'

     errorlevel -207,-302,-305,-306


;**************************************************************************
;                                                                         *
; Specification                                                           *
;                                                                         *
;**************************************************************************

; power-up self-test - double beep and motor runs briefly

; pushbutton cycles through modes (light, moderate, heavy infestation)
; 1 to 3 beeps indicates mode, initially mode 2

; pushbutton held down for 2s toggles demo mode (long beep)

; mice activity (squeaks and feet/tail movement) triggered periodically
; frequency and level dependent on mode, semi-continuous in demo mode

; position on sheet of paper or in open cardboard box for maximum effect
; hide in inaccessible place (under bed, on top of wardrobe etc.)


;**************************************************************************
;                                                                         *
; Port assignments                                                        *
;                                                                         *
;**************************************************************************

GPIO_IO        equ  b'101010'      ; port I/O status

MOTOR          equ  0              ; motor
BUTTON         equ  1              ; pushbutton
SPEAKER1       equ  2              ; speaker
SPEAKER2       equ  4


;**************************************************************************
;                                                                         *
; Constants and timings                                                   *
;                                                                         *
;**************************************************************************

CLOCK          equ  d'4000000'     ; processor clock frequency in Hz

MOTOR_PERIOD   equ  d'4'           ; motor duty cycle period in ms

MAX_SPEED      equ  d'50'          ; maximum motor speed

BEEP_PITCH     equ  d'30'          ; beep pitch
BEEP_PERIOD    equ  d'200'         ; beep period

SQUEAK_PITCH   equ  d'18'          ; squeak pitch
SQUEAK_PERIOD  equ  d'175'         ; squeak period
SQUEAK_SPREAD  equ  h'3f'          ; squeak spread

ACTIVITY1      equ  d'20'          ; periods between
ACTIVITY2      equ  d'15'          ; mice activity
ACTIVITY3      equ  d'10'          ; in minutes


;**************************************************************************
;                                                                         *
; File register usage                                                     *
;                                                                         *
;**************************************************************************

     ifdef __12F629
RAM  equ  h'20'
     endif
     ifdef __12C508A
RAM  equ  h'07'
     endif

     cblock RAM
     flags                    ; various flags
     mode                     ; mode, 0 to 2
     duty                     ; motor duty cycle, 0 (off) to 100 (on)
     speed                    ; motor speed, 0 to 100
     timer:2                  ; timer
     ndx                      ; table index
     loop                     ; loop counter
     repeat                   ; repeat counter
     count:2                  ; scratch counter
     rand_l, rand_h           ; random number
     work1, work2             ; work registers
     endc

; flags
POLL      equ  0              ; set if pushbutton polled
DEMO      equ  1              ; set if demo mode


;**************************************************************************
;                                                                         *
; Macros                                                                  *
;                                                                         *
;**************************************************************************

routine   macro label              ; routine
label
          endm

table     macro label              ; define lookup table
label     addwf PCL
          endm

entry     macro value              ; define table entry
          retlw value
          endm

index     macro label              ; index lookup table
          call label
          endm

jump      macro label              ; jump through table
          goto label
          endm

tstw      macro                    ; test w register
          iorlw 0
          endm

movff     macro f1,f2              ; move file to file
          movfw f1
          movwf f2
          endm

movlf     macro n,f                ; move literal to file
          movlw n
          movwf f
          endm

tris_     macro t
          movlw t
          ifdef __12F629
          bsf STATUS,RP0
          movwf TRISIO
          bcf STATUS,RP0
          endif
          ifdef __12C508A
          tris GPIO
          endif
          endm


;--------------------------------------------------------------------------
; reset vector
;--------------------------------------------------------------------------

          org 0

          ifdef __12F629
          bsf STATUS,RP0
          call h'3ff'
          movwf OSCCAL
          bcf STATUS,RP0
          endif
          ifdef __12C508A
          movwf OSCCAL
          endif

          goto main_entry


;**************************************************************************
;                                                                         *
; Lookup tables                                                           *
;                                                                         *
;**************************************************************************

          table moves_table

range     macro base,spread
          entry base
          entry spread
          endm

; repeat - period - wait - loop - wait

          range d'2',h'02'              ; mode 1
          range d'18',h'03'
          range d'12',h'0f'
          range d'2',h'03'
          range d'15',h'0f'

          range d'3',h'03'              ; mode 2
          range d'16',h'07'
          range d'12',h'0f'
          range d'3',h'03'
          range d'12',h'0f'

          range d'4',h'03'              ; mode 3
          range d'14',h'0f'
          range d'10',h'1f'
          range d'5',h'03'
          range d'12',h'0f'


;**************************************************************************
;                                                                         *
; Procedures                                                              *
;                                                                         *
;**************************************************************************

;--------------------------------------------------------------------------
; delay
;--------------------------------------------------------------------------

          nop                           ; [4]
          nop                           ; [4]
          nop                           ; [4]
          nop                           ; [4]
          nop                           ; [4]
          nop                           ; [4]
delay16   retlw 0                       ; [8]

          nop                           ; [4]
          nop                           ; [4]
ldelay    movwf work1                   ; [4]
ldel1     decfsz work1                  ; [4/8]
          goto ldel1                    ; [8/0]
          retlw 0                       ; [8]

delay     macro cycles                  ; delay for a number of cycles

          if (cycles) < 0
          error "Delay negative cycles"
          endif

          variable i = cycles

          if i > d'40'

          variable n = (i-d'20')/d'12'
          i -= (n*d'12')+d'20'
          variable m = i/d'4'
          i = 0

          movlw n                       ; [4]
          call ldelay-m                 ; [8]

          else
          if i >= d'16'

          variable n = (i-d'16')/d'4'
          i -= (n*d'4')+d'16'

          call delay16-n                ; [8]

          endif
          endif

          while i > 0
          nop                           ; [4]
          i -= d'4'
          endw

          endm


;--------------------------------------------------------------------------
; waits, fed with the wait in 10ms in the w reg
;--------------------------------------------------------------------------

          routine wait

          movwf count

wait1     movlf d'10',work1

wait2     movlf CLOCK/(d'1000'*d'20'),work2

wait3     clrwdt                        ; [4]
          nop                           ; [4]
          decfsz work2                  ; [4]
          goto wait3                    ; [8]

          decfsz work1
          goto wait2

          btfss flags,POLL              ; button polled ?
          goto wait4                    ; branch if not

          bsf GPIO,BUTTON               ; button pressed ?
          nop
          btfss GPIO,BUTTON
          goto next_mode                ; branch if yes

wait4     decfsz count
          goto wait1

          retlw 0


;--------------------------------------------------------------------------
; generates a pseudo random number in the range 0 to 15
;--------------------------------------------------------------------------

          routine get_random

          movfw rand_l
          iorwf rand_h,w
          bnz getr1

          movfw TMR0                    ; seed generator
          movwf rand_l
          xorlw h'ff'
          movwf rand_h

getr1     rlf rand_h,w                  ; calculate next in sequence
          xorwf rand_h,w
          movwf work1                   ; msb <= Q15 ^ Q14
          swapf rand_l,w
          btfsc rand_h,4
          xorlw h'80'                   ; msb <= Q12 ^ Q3
          xorwf work1
          rlf work1
          rlf rand_l
          rlf rand_h                    ; << 1 + (Q15 ^ Q14 ^ Q12 ^ Q3)

          retlw 0


;--------------------------------------------------------------------------
; beeps
;--------------------------------------------------------------------------

          routine beep

          movlf BEEP_PERIOD,work1

beep1     movlf 1<<SPEAKER1,GPIO        ; speaker on

          movlf BEEP_PITCH,work2        ; half-cycle delay
beep2     clrwdt
          decfsz work2
          goto beep2

          movlf 1<<SPEAKER2,GPIO        ; speaker on

          movlf BEEP_PITCH,work2        ; half-cycle delay
beep3     clrwdt
          decfsz work2
          goto beep3

          decfsz work1
          goto beep1

          clrf GPIO                     ; speaker off

          retlw 0


;--------------------------------------------------------------------------
; squeaks
;--------------------------------------------------------------------------

          routine squeak

          movlf high SQUEAK_PERIOD,count+0
          movlf low SQUEAK_PERIOD,count+1
          movfw rand_l
          andlw SQUEAK_SPREAD
          addwf count+1
          skpnc
          incf count+0

squeak1   nop                           ; speaker on [4]
          nop                           ; [4]
          movlw 1<<SPEAKER1             ; [4]
          movwf GPIO                    ; [4]

          movlf SQUEAK_PITCH,work1      ; half-cycle delay
squeak2   clrwdt
          decfsz work1
          goto squeak2

          delay d'20'

          bsf GPIO,BUTTON               ; button pressed ? [4]
          nop                           ; [4]
          btfss GPIO,BUTTON             ; [8]
          goto next_mode                ; branch if yes

          movfw mode                    ; speaker on [4]
          skpz                          ; [8/4]
          movlw 1<<SPEAKER2             ; [0/4]
          movwf GPIO                    ; [4]

          movlf SQUEAK_PITCH,work1      ; half-cycle delay
squeak3   clrwdt
          decfsz work1
          goto squeak3

          tstf count+1                  ; [4]
          skpnz                         ; [8/4]
          decf count+0                  ; [0/4]
          decf count+1                  ; [4]

          movfw count+0                 ; [4]
          iorwf count+1,w               ; [4]
          bnz squeak1                   ; [12]

          clrf GPIO                     ; speaker off

          retlw 0


;--------------------------------------------------------------------------
; motor pwm control, fed with the period in 10ms in the w reg
;--------------------------------------------------------------------------

          routine pwm

          movwf count+0

          movlf d'10',count+1

pwm1      bcf GPIO,MOTOR

DELAY     set  (MOTOR_PERIOD*CLOCK)/(d'1000'*MAX_SPEED)

          movlf MAX_SPEED,work2

pwm2      clrwdt                        ; [4]

          movfw duty                    ; [4]
          subwf work2,w                 ; [4]
          skpnz                         ; [8/4]
          bsf GPIO,MOTOR                ; motor on [0/4]

          delay DELAY-d'32'

          decfsz work2                  ; [4]
          goto pwm2                     ; [8]

          movfw speed                   ; adjust duty cycle
          subwf duty,w
          skpc
          incf duty                     ; ramp up
          movfw speed
          skpnc
          movwf duty                    ; cap

          movlw MOTOR_PERIOD
          subwf count+1
          bz pwm3
          bc pwm1

pwm3      movlw d'10'
          addwf count+1

          btfss flags,POLL              ; button polled ?
          goto pwm4                     ; branch if not

          bsf GPIO,BUTTON               ; button pressed ?
          nop
          btfss GPIO,BUTTON
          goto next_mode                ; branch if yes

pwm4      decfsz count+0
          goto pwm1

          clrf GPIO                     ; motor off

          retlw 0


;--------------------------------------------------------------------------
; randomizes an attribute
;--------------------------------------------------------------------------

randomize      macro offset

          call get_random

          movlw offset
          addwf ndx,w
          movwf work1

          index moves_table             ; base
          movwf work2

          incf work1,w                  ; spread
          index moves_table
          andwf rand_h,w
          addwf work2,w

          endm


;--------------------------------------------------------------------------
; mice sound
;--------------------------------------------------------------------------

do_sound       macro

          call get_random
          movfw rand_h
          andlw h'03'
          movwf repeat
          movlw d'1'
          addwf repeat
          tstf mode
          skpz
          incf repeat

dos1      call get_random
          call squeak

          movlw d'15'
          call wait

          decfsz repeat
          goto dos1

          endm


;--------------------------------------------------------------------------
; mice movement
;--------------------------------------------------------------------------

do_movement    macro

          randomize d'0'
          movwf repeat

dom1      movlf MAX_SPEED,speed
          clrf duty

          randomize d'2'
          call pwm

          randomize d'4'
          call wait

          decfsz repeat
          goto dom1

          endm


;--------------------------------------------------------------------------
; mice activity
;--------------------------------------------------------------------------

do_activity    macro

          bsf flags,POLL

          movfw mode
          addwf mode,w
          addwf mode,w
          addwf mode,w
          addwf mode,w
          movwf ndx
          clrc
          rlf ndx                       ; mode * 10

          randomize d'6'
          movwf loop

doa1      call get_random
          movfw rand_h
          andlw h'03'
          bz doa2

          do_movement

          goto doa3

doa2      do_sound

doa3      randomize d'8'
          call wait

          decfsz loop
          goto doa1

          endm


;--------------------------------------------------------------------------
; next mode
;--------------------------------------------------------------------------

          routine next_mode

          bcf flags,POLL

          movlf d'200',timer

nextm1    movlw 1                       ; wait for button to be released
          call wait

          decf timer                    ; button held down ?
          bz demo_mode                  ; branch if yes

          bsf GPIO,BUTTON
          nop
          btfss GPIO,BUTTON
          goto nextm1

          incf mode                     ; cycle mode
          incf mode,w
          andlw b'100'
          skpz
          clrf mode

          incf mode,w                   ; 1, 2 or 3 beeps
          movwf repeat
nextm2    call beep
          movlw d'15'
          call wait
          decfsz repeat
          goto nextm2

          movlw d'25'
          call wait

          goto main_loop


;--------------------------------------------------------------------------
; demo mode
;--------------------------------------------------------------------------

          routine demo_mode

          bcf flags,POLL

          call beep                     ; long beep
          call beep
          call beep
          call beep
          call beep
          call beep
          call beep

demom1    movlw 1                       ; wait for button to be released
          call wait

          bsf GPIO,BUTTON
          nop
          btfss GPIO,BUTTON
          goto demom1

          movlw 1<<DEMO                 ; toggle demo mode
          xorwf flags

          movlw d'25'
          call wait

          goto main_loop


;--------------------------------------------------------------------------
; main entry point
;--------------------------------------------------------------------------

          routine main_entry

          clrf GPIO                     ; initialise port
          tris_ GPIO_IO

          ifdef __12F629
          bsf STATUS,RP0                ; prescale RTCC 1:2,
          movlw b'00000000'             ; weak pull-ups enabled
          movwf OPTION_REG
          movlf 1<<BUTTON,WPU
          bcf STATUS,RP0
          endif
          ifdef __12C508A
          movlw b'10000000'             ; prescale RTCC 1:2,
          option                        ; weak pull-ups enabled
          endif

          ifdef __12F629                ; wake-up on pin change ?
          btfsc INTCON,GPIF
          endif
          ifdef __12C508A
          btfsc STATUS,GPWUF
          endif
          goto main1                    ; branch if yes

          movfw STATUS                  ; wake-up from sleep ?
          andlw (1<<NOT_TO)+(1<<NOT_PD)
          clrwdt
          bz main2                      ; branch if yes

          clrf rand_l                   ; clear random number
          clrf rand_h

          clrf flags                    ; clear flags

          movlf 1,mode                  ; initial mode

          call beep                     ; double beep
          movlw d'15'
          call wait
          call beep

          movlf MAX_SPEED,speed         ; run motor
          clrf duty
          movlw d'50'
          call pwm

          clrf GPIO                     ; motor off
          clrf speed
          clrf duty

          movlw d'50'
          call wait

          goto main_loop

main1     goto next_mode

main2     tstf timer+1                  ; decrement timer
          skpnz
          decf timer+0
          decf timer+1

          movfw timer+0
          iorwf timer+1,w
          bz main_loop
;         goto sleep_state


;--------------------------------------------------------------------------
; sleep state
;--------------------------------------------------------------------------

          routine sleep_state

          clrf GPIO                     ; speaker and motor off

          ifdef __12F629
          bsf STATUS,RP0                ; prescale WDT 1:128, weak pull-ups
          movlw b'00001111'             ; enabled, wake-up on pin change
          movwf OPTION_REG
          movlf 1<<BUTTON,IOCB
          bcf STATUS,RP0
          bsf INTCON,GPIE
          bcf INTCON,GPIF
          endif
          ifdef __12C508A
          movlw b'00001111'             ; prescale WDT 1:128, weak pull-ups
          option                        ; enabled, wake-up on pin change
          endif

          clrwdt

          tris_ 1<<BUTTON               ; read port
          movwf GPIO
          nop
          movfw GPIO

          sleep                         ; standby mode

          goto main_entry


;--------------------------------------------------------------------------
; main loop
;--------------------------------------------------------------------------

          routine main_loop

          clrwdt                        ; clear watchdog timer

          clrf GPIO                     ; re-initialise port
          tris_ GPIO_IO

          ifdef __12F629
          bsf STATUS,RP0                ; prescale RTCC 1:2,
          movlw b'00000000'             ; weak pull-ups enabled
          movwf OPTION_REG
          movlf 1<<BUTTON,WPU
          bcf STATUS,RP0
          endif
          ifdef __12C508A
          movlw b'10000000'             ; prescale RTCC 1:2,
          option                        ; weak pull-ups enabled
          endif

          ifdef __12F629
          clrf INTCON                   ; interrupts off
          endif

          ifdef __12F629
          movlf b'111',CMCON
          clrf PCLATH
          endif

          do_activity

          clrf timer+0
          movlf d'4',timer+1
          btfsc flags,DEMO
          goto sleep_state

MINUTE    equ  d'23'

          movlf high ((ACTIVITY1-1)*MINUTE),timer+0
          movlf low ((ACTIVITY1-1)*MINUTE),timer+1
          tstf mode
          bz loop1
          movlf high ((ACTIVITY2-1)*MINUTE),timer+0
          movlf low ((ACTIVITY2-1)*MINUTE),timer+1
          decf mode,w
          bz loop1
          movlf high ((ACTIVITY3-1)*MINUTE),timer+0
          movlf low ((ACTIVITY3-1)*MINUTE),timer+1

loop1     call get_random
          movfw rand_l
          andlw h'3f'
          addwf timer+1
          skpnc
          incf timer+0

          goto sleep_state


          ifdef __12C508A
;         org h'1ff'                    ; *** comment for OTP part ***
;         goto main_entry
          endif


          end