;**************************************************************************
; FILE:      psi-q.asm                                                    *
; CONTENTS:  Psi-Q Tester                                                 *
; COPYRIGHT: MadLab Ltd. 2000                                             *
; AUTHOR:    James Hutchby                                                *
; UPDATED:   09/04/00                                                     *
;**************************************************************************

     list p=16C56A
;    list p=16F84

     ifdef __16C56A
     include "p16c5x.inc"
     endif
     ifdef __16F84
     include "p16f84.inc"
     endif

     ifdef __16C56A
     __config _RC_OSC & _WDT_ON & _CP_ON
     endif
     ifdef __16F84
     __config _RC_OSC & _WDT_ON & _PWRTE_ON & _CP_OFF
     endif

     __idlocs h'CA10'

     errorlevel -305,-306


;**************************************************************************
;                                                                         *
; Specification                                                           *
;                                                                         *
;**************************************************************************

; power-up self-test - all LEDs flash twice

; welcome message displayed until pushbutton pressed
; alternate flashing question marks displayed
; pushbutton selects left or right
; correct => tick, incorrect => cross
; first 30 guesses counted down, then psi-q factor displayed
; sleeps after period of inactivity, wakes when pushbutton pressed

; within 1 sigma - 67%
; within 2 sigma - 95%
; within 3 sigma - 99.8%
; within 4 sigma - 99.99%
; within 5 sigma - 100%

; serial link between two units
; master transmits left/right selection and correct/incorrect to slave
; slave displays left/right selection and correct/incorrect
; pushbutton exits slave mode


;**************************************************************************
;                                                                         *
; Port assignments                                                        *
;                                                                         *
;**************************************************************************

PORTA_IO  equ  b'11111'            ; port A I/O status
PORTB_IO  equ  b'00100101'         ; port B I/O status

ROW1      equ       1              ; LED rows
ROW2      equ       3
ROW3      equ       4
ROW4      equ       7
ROW5      equ       6

WEIGHT    equ       0              ; spare bits
SPARE1    equ       2
SPARE2    equ       5

#define   COLUMN1   PORTA,2        ; LED columns
#define   COLUMN2   PORTA,3
#define   COLUMN3   PORTB,0
#define   COLUMN4   PORTA,1
#define   COLUMN5   PORTB,2
#define   COLUMN6   PORTA,0
#define   COLUMN7   PORTB,5

PIXELS_MASK    equ  b'11011010'

BUS       equ  7         ; 1-wire bus

BUTTON1   equ  2         ; pushbutton 1 (port A)
BUTTON2   equ  2         ; pushbutton 2 (port B)


;**************************************************************************
;                                                                         *
; Constants and timings                                                   *
;                                                                         *
;**************************************************************************

CLOCK     equ  d'3500000'     ; processor clock frequency in Hz

          ifdef __16C56A
PRESCALE  equ  b'101111'      ; prescale WDT 1:128, external rising edge
          endif
          ifdef __16F84
PRESCALE  equ  b'10101111'    ; weak pull-ups disabled
          endif

FLIPS     equ  d'30'          ; initial number of flips

; repeat counts
WELCOME_REPEAT      equ  d'10'
QUESTION_REPEAT     equ  d'250'
TX_REPEAT           equ  d'4'

; delays in 1/100 s
POLL_DELAY          equ  d'4'
SCROLL_DELAY        equ  d'20'
QUESTION_DELAY      equ  d'40'
PRESSED_DELAY       equ  d'50'
RESULT_DELAY        equ  d'75'
HITS_DELAY          equ  d'125'
SPIRAL_DELAY        equ  d'5'

; 1-wire bus timings in 100 us
BUS_INTRO           equ  d'250'
BUS_CLOCK           equ  d'1'
BUS_DATA            equ  d'10'

; 1-wire bus instructions
INSTR_LEFT          equ  b'00'          ; display left selection
INSTR_RIGHT         equ  b'01'          ; display right selection
INSTR_TICK          equ  b'10'          ; display tick
INSTR_CROSS         equ  b'11'          ; display cross


;**************************************************************************
;                                                                         *
; File register usage                                                     *
;                                                                         *
;**************************************************************************

     ifdef __16C56A
RAM  set  h'07'
MAX  set  h'20'
     endif
     ifdef __16F84
RAM  set  h'0c'
MAX  set  h'50'
     endif

     cblock RAM
     flags                    ; various flags
     rand_l, rand_h           ; random number
     seed                     ; random seed
     flips:2                  ; number of flips
     hits:2                   ; number of hits
     pixels:7                 ; LED pixels
     count                    ; scratch counter
     loop                     ; loop counter
     timer                    ; timer
     window:0, ndx            ; message window / index
     pnt                      ; pointer
     mask                     ; bit mask
     instr                    ; instruction
     work1, work2, work3      ; work registers
     RAM_
     endc

     if RAM_ > MAX
     error "File register usage overflow"
     endif

; flags
RELEASE        equ  0         ; set if waiting for pushbutton release
PRESSED1       equ  1         ; set if pushbutton 1 pressed
PRESSED2       equ  2         ; set if pushbutton 2 pressed
LEFTRIGHT      equ  3         ; left/right random selection
TICKCROSS      equ  4         ; correct/incorrect
SPIRAL         equ  5         ; spiral draw/undraw
IGNORE         equ  6         ; ignore serial link

PRESSED_MASK   equ  (1<<PRESSED1)|(1<<PRESSED2)


;**************************************************************************
;                                                                         *
; Macros                                                                  *
;                                                                         *
;**************************************************************************

routine   macro label              ; routine
label
          endm

table     macro label              ; define lookup table
label     addwf PCL
          endm

entry     macro value              ; define table entry
          retlw value
          endm

index     macro label              ; index lookup table
          call label
          endm

jump      macro label              ; jump through table
          goto label
          endm

tstw      macro                    ; test w register
          iorlw 0
          endm

movff     macro f1,f2              ; move file to file
          movfw f1
          movwf f2
          endm

movlf     macro n,f                ; move literal to file
          movlw n
          movwf f
          endm

tris_A    macro                    ; tristate port A
          ifdef __16C56A
          tris PORTA
          endif
          ifdef __16F84
          bsf STATUS,RP0
          movwf TRISA&h'7f'
          bcf STATUS,RP0
          endif
          endm

tris_B    macro                    ; tristate port B
          ifdef __16C56A
          tris PORTB
          endif
          ifdef __16F84
          bsf STATUS,RP0
          movwf TRISB&h'7f'
          bcf STATUS,RP0
          endif
          endm

option_   macro                    ; set options
          ifdef __16C56A
          option
          endif
          ifdef __16F84
          bsf STATUS,RP0
          movwf OPTION_REG&h'7f'
          bcf STATUS,RP0
          endif
          endm

page0     macro                    ; select page 0
          ifdef __16C56A
          bcf STATUS,PA0
          endif
          endm

page1     macro                    ; select page 1
          ifdef __16C56A
          bsf STATUS,PA0
          endif
          endm


;--------------------------------------------------------------------------
; page #0
;--------------------------------------------------------------------------

          org 0


;--------------------------------------------------------------------------
; reset vector
;--------------------------------------------------------------------------

          ifdef __16F84

          goto main_entry

          endif


;**************************************************************************
;                                                                         *
; Lookup tables                                                           *
;                                                                         *
;**************************************************************************

          table enable                  ; column enable

AorB      equ  4

          entry (1<<2)|(0<<AorB)
          entry (1<<3)|(0<<AorB)
          entry (1<<0)|(1<<AorB)
          entry (1<<1)|(0<<AorB)
          entry (1<<2)|(1<<AorB)
          entry (1<<0)|(0<<AorB)
          entry (1<<5)|(1<<AorB)


LEDS      macro pix

leds      set  0
bits      set  0

          if (pix)&(1<<4)
leds      set  leds|(1<<ROW1)
bits      set  bits+1
          endif
          if (pix)&(1<<3)
leds      set  leds|(1<<ROW2)
bits      set  bits+1
          endif
          if (pix)&(1<<2)
leds      set  leds|(1<<ROW3)
bits      set  bits+1
          endif
          if (pix)&(1<<1)
leds      set  leds|(1<<ROW4)
bits      set  bits+1
          endif
          if (pix)&(1<<0)
leds      set  leds|(1<<ROW5)
bits      set  bits+1
          endif

          if (pix)&(1<<5)
leds      set  leds|(1<<SPARE1)
          endif
          if (pix)&(1<<6)
leds      set  leds|(1<<SPARE2)
          endif

          if bits > 3
leds      set  leds|(1<<WEIGHT)
          endif

          entry leds

          endm


QUESTION  LEDS b'10000'                 ; question mark
          LEDS b'10101'
          LEDS b'01000'

LEFT      LEDS b'11111'                 ; select left
          LEDS b'11111'
          LEDS b'11111'
          LEDS b'11111'
RIGHT     LEDS b'00000'                 ; select right
          LEDS b'00000'
          LEDS b'00000'
          LEDS b'11111'
          LEDS b'10001'
          LEDS b'10001'
          LEDS b'11111'

FACTOR    LEDS b'11111'                 ; F
          LEDS b'10100'
          LEDS b'10000'

ZERO      LEDS b'11111'                 ; 0
          LEDS b'10001'
          LEDS b'11111'

          LEDS b'01001'                 ; 1
          LEDS b'11111'
          LEDS b'00001'

          LEDS b'10111'                 ; 2
          LEDS b'10101'
          LEDS b'11101'

          LEDS b'10101'                 ; 3
          LEDS b'10101'
          LEDS b'11111'

          LEDS b'11110'                 ; 4
          LEDS b'00111'
          LEDS b'00010'

          LEDS b'11101'                 ; 5
          LEDS b'10101'
          LEDS b'10111'

          LEDS b'11111'                 ; 6
          LEDS b'10101'
          LEDS b'10111'

          LEDS b'10011'                 ; 7
          LEDS b'10100'
          LEDS b'11000'

          LEDS b'11111'                 ; 8
          LEDS b'10101'
          LEDS b'11111'

          LEDS b'11101'                 ; 9
          LEDS b'10101'
          LEDS b'11111'

TICK      LEDS b'00100'                 ; tick
          LEDS b'00010'
          LEDS b'00001'
          LEDS b'00010'
          LEDS b'00100'
          LEDS b'01000'
          LEDS b'10000'

CROSS     LEDS b'00000'                 ; cross
          LEDS b'10001'
          LEDS b'01010'
          LEDS b'00100'
          LEDS b'01010'
          LEDS b'10001'
          LEDS b'00000'


          table welcome                 ; welcome message

char1     macro c1
          LEDS c1|(1<<5)
          endm

char2     macro c1,c2
          LEDS c1
          LEDS c2|(1<<5)
          endm

char3     macro c1,c2,c3
          LEDS c1
          LEDS c2
          LEDS c3|(1<<5)
          endm

char4     macro c1,c2,c3,c4
          LEDS c1
          LEDS c2
          LEDS c3
          LEDS c4|(1<<5)
          endm

          char1 b'00000'                               ; ' '
          char1 b'00000'                               ; ' '
          char1 b'00000'                               ; ' '

          char3 b'11111',b'10100',b'01000'             ; 'P'
          char3 b'01001',b'10101',b'10010'             ; 'S'
          char3 b'10001',b'11111',b'10001'             ; 'I'
          char3 b'00100',b'00100',b'00100'             ; '-'
          char4 b'01110',b'10001',b'10011',b'01110'    ; 'Q'

          char2 b'00000',b'00000'                      ; ' '

          char3 b'10000',b'11111',b'10000'             ; 'T'
          char3 b'11111',b'10101',b'10001'             ; 'E'
          char3 b'01001',b'10101',b'10010'             ; 'S'
          char3 b'10000',b'11111',b'10000'             ; 'T'
          char3 b'11111',b'10101',b'10001'             ; 'E'
          char3 b'11111',b'10110',b'01001'             ; 'R'

          char2 b'00000',b'00000'                      ; ' '

          char3 b'11111',b'10101',b'01010'             ; 'B'
          char3 b'11000',b'00111',b'11000'             ; 'Y'

          char2 b'00000',b'00000'                      ; ' '

          char3 b'11111',b'01000',b'11111'             ; 'M'
          char3 b'01111',b'10100',b'01111'             ; 'A'
          char3 b'11111',b'10001',b'01110'             ; 'D'
          char3 b'11111',b'00001',b'00001'             ; 'L'
          char3 b'01111',b'10100',b'01111'             ; 'A'
          char3 b'11111',b'10101',b'01010'             ; 'B'

          char1 b'00000'                               ; ' '
          char1 b'00000'                               ; ' '
          char1 b'00000'                               ; ' '

          entry -1


          table spiral                  ; spiral pattern

          entry (1<<ROW5)|(1<<SPARE2)
          entry d'7'
          entry (1<<ROW4)|(1<<SPARE1)
          entry (1<<ROW3)|(1<<SPARE1)
          entry (1<<ROW2)|(1<<SPARE1)
          entry (1<<ROW1)|(0<<SPARE2)
          entry d'7'
          entry (1<<ROW2)|(1<<SPARE1)
          entry (1<<ROW3)|(1<<SPARE1)
          entry (1<<ROW4)|(1<<SPARE2)
          entry d'6'
          entry (1<<ROW3)|(1<<SPARE1)
          entry (1<<ROW2)|(0<<SPARE2)
          entry d'5'
          entry (1<<ROW3)|(1<<SPARE2)
          entry d'4'
          entry 0


          table sigma                   ; standard deviations

          entry d'4'-d'0'               ; 1
          entry d'15'-d'4'              ; 2
          entry d'37'-d'15'             ; 3
          entry d'63'-d'37'             ; 4
          entry d'101'-d'63'            ; 5
          entry d'144'-d'101'           ; 6
          entry d'195'-d'144'           ; 7
          entry d'257'-d'195'           ; 8
          entry d'323'-d'257'           ; 9
          entry d'398'-d'323'           ; 10
          entry d'482'-d'398'           ; 11
          entry d'573'-d'482'           ; 12
          entry d'674'-d'573'           ; 13
          entry d'775'-d'674'           ; 14
          entry d'895'-d'775'           ; 15
          entry d'1022'-d'895'          ; 16
          entry d'1146'-d'1022'         ; 17
          entry d'1291'-d'1146'         ; 18
          entry d'1436'-d'1291'         ; 19
          entry d'1592'-d'1436'         ; 20
          entry 0


;**************************************************************************
;                                                                         *
; Procedures                                                              *
;                                                                         *
;**************************************************************************

lookup    movwf PCL                     ; look up table


;--------------------------------------------------------------------------
; page #1 vectors
;--------------------------------------------------------------------------

vector    macro addr1,addr2
addr1     page1
          goto addr2
          endm

          vector tx_bus,tx_bus_
          vector delay,delay_
          vector poll,poll_
          vector clear,clear_
          vector show_left,show_left_
          vector show_right,show_right_
          vector show_character,show_character_
          vector get_random,get_random_
          vector calc_factor,calc_factor_


;--------------------------------------------------------------------------
; prints the number in w reg
;--------------------------------------------------------------------------

print_num      macro

          movwf count
          clrf work1
print1    movlw d'10'
          subwf count
          bnc print2
          incf work1
          goto print1
print2    addwf count

          call clear

          movlw ZERO                    ; tens
          addwf work1,w
          addwf work1,w
          addwf work1,w
          call show_left

          movlw ZERO                    ; units
          addwf count,w
          addwf count,w
          addwf count,w
          call show_right

          endm


;--------------------------------------------------------------------------
; waits until a pushbutton is pressed
;--------------------------------------------------------------------------

wait      macro period,exit

          local wait1

          movlf period/POLL_DELAY,count

wait1     movlw POLL_DELAY
          call delay

          call poll                     ; pushbutton pressed ?
          bnz exit                      ; branch if yes

          decfsz count
          goto wait1

          endm


;--------------------------------------------------------------------------
; draws a spiral
;--------------------------------------------------------------------------

draw_spiral    macro

          bcf flags,SPIRAL

draw0     movlf pixels+6,pnt

          clrf ndx

draw1     movfw ndx
          index spiral
          movwf mask

          tstw                          ; end of spiral ?
          bz draw4                      ; branch if yes

          incf ndx
          movfw ndx
          index spiral
          movwf count

draw2     movff pnt,FSR
          movfw mask
          xorwf 0

          movlw SPIRAL_DELAY
          call delay

          call poll                     ; pushbutton pressed ?
          bnz draw5                     ; branch if yes

          btfsc mask,SPARE1
          goto draw1

          decf count
          bz draw3

          btfsc mask,SPARE2
          decf pnt
          btfss mask,SPARE2
          incf pnt

          goto draw2

draw3     incf ndx

          goto draw1

draw4     movlw SPIRAL_DELAY
          call delay

          btfsc flags,SPIRAL
          goto draw5

          bsf flags,SPIRAL
          goto draw0

draw5     bcf flags,RELEASE

          endm


;--------------------------------------------------------------------------
; displays the welcome message
;--------------------------------------------------------------------------

          routine display_message

          movlf WELCOME_REPEAT,timer

dispm1    clrf window                   ; initialise message window

dispm2    movlf pixels,FSR
          movlf d'7',work1

          clrf pnt

dispm3    clrf 0                        ; spacer ?
          clrc
          rrf window,w
          bc dispm4                     ; branch if yes

          index welcome                 ; get the next pixels
          movwf 0

          incf 0,w                      ; end of message ?
          bz dispm5                     ; branch if yes

          incf window                   ; next column
          btfss 0,SPARE1
dispm4    incf window

          movfw window                  ; save next window
          tstf pnt
          skpnz
          movwf pnt

          incf FSR
          decfsz work1
          goto dispm3                   ; loop for all columns

          wait SCROLL_DELAY,main_loop

          movff pnt,window              ; scroll message

          goto dispm2

dispm5    call clear                    ; draw then undraw a spiral
          draw_spiral

          decfsz timer                  ; timeout ?
          goto dispm1
          goto sleep_state              ; sleep if yes


;--------------------------------------------------------------------------
; main entry point
;--------------------------------------------------------------------------

          routine main_entry

          clrf PORTA                    ; initialise ports
          movlw PORTA_IO
          tris_A
          clrf PORTB
          movlw PORTB_IO
          tris_B

          movlw PRESCALE
          option_

          movfw STATUS                  ; wake-up from sleep ?
          andlw (1<<NOT_TO)+(1<<NOT_PD)
          clrwdt
          bz main2                      ; branch if yes

          clrf flags

          call clear                    ; self test
          movlf d'4',count
main1     comf pixels+0
          comf pixels+1
          comf pixels+2
          comf pixels+3
          comf pixels+4
          comf pixels+5
          comf pixels+6
          movlw d'25'
          call delay
          decfsz count
          goto main1

          clrf rand_l                   ; clear random number
          clrf rand_h

          clrf flips+0                  ; clear number of flips and hits
          clrf flips+1
          clrf hits+0
          clrf hits+1

          bsf flags,RELEASE             ; signal waiting for release

          goto main3

main2     call poll                     ; pushbutton pressed ?
          bz sleep_state                ; branch if not

main3     goto display_message


;--------------------------------------------------------------------------
; sleep state
;--------------------------------------------------------------------------

          routine sleep_state

          clrf PORTA                    ; LEDs off
          clrf PORTB

          ifdef __16C56A                ; prescale WDT 1:4
          movlw b'101010'
          endif
          ifdef __16F84
          movlw b'10101010'
          endif
          option_

          clrwdt

          sleep                         ; standby mode

          ifdef __16F84
          goto main_entry
          endif


;--------------------------------------------------------------------------
; main loop
;--------------------------------------------------------------------------

          routine main_loop

          call get_random               ; randomly select left or right
          bcf flags,LEFTRIGHT
          btfsc rand_l,0
          bsf flags,LEFTRIGHT

          movlf TX_REPEAT,count         ; transmit left/right selection
loop1     movlw INSTR_LEFT              ; on 1-wire bus
          btfsc flags,LEFTRIGHT
          movlw INSTR_RIGHT
          call tx_bus
          decfsz count
          goto loop1

          movlf QUESTION_REPEAT,timer

loop2     call clear
          movlw QUESTION
          btfsc timer,0
          call show_left
          btfss timer,0
          call show_right

          wait QUESTION_DELAY,loop3

          decfsz timer                  ; timeout ?
          goto loop2
          goto display_message          ; branch if yes

loop3     call clear
          movlw LEFT
          btfss flags,PRESSED2
          call show_character
          movlw RIGHT
          btfss flags,PRESSED1
          call show_character
          movlw PRESSED_DELAY
          call delay

          bcf flags,TICKCROSS
          btfsc flags,LEFTRIGHT
          goto loop4
          btfsc flags,PRESSED1
          btfsc flags,PRESSED2
          bsf flags,TICKCROSS
          goto loop5
loop4     btfss flags,PRESSED1
          btfss flags,PRESSED2
          bsf flags,TICKCROSS

loop5     btfsc flags,TICKCROSS         ; increment number of hits
          goto loop6                    ; if correct
          incf hits+1
          skpnz
          incf hits+0

loop6     incf flips+1                  ; increment number of flips
          skpnz
          incf flips+0

          movlf TX_REPEAT,count         ; transmit correct/incorrect
loop7     movlw INSTR_TICK              ; on 1-wire bus
          btfsc flags,TICKCROSS
          movlw INSTR_CROSS
          call tx_bus
          decfsz count
          goto loop7

          movlw TICK                    ; display tick if correct
          btfsc flags,TICKCROSS         ; else display cross
          movlw CROSS
          call show_character
          movlw RESULT_DELAY
          call delay

          tstf flips+0                  ; initial flips ?
          bnz loop8
          movlw FLIPS
          subwf flips+1,w
          bc loop8                      ; branch if not

          movwf work1                   ; display remaining flips
          comf work1
          incf work1,w
          print_num

          goto loop9

loop8     call calc_factor              ; calculate psi-q factor

          call clear                    ; display factor
          movlw FACTOR
          call show_left
          movlw ZERO
          addwf count,w
          addwf count,w
          addwf count,w
          call show_right

loop9     movlw HITS_DELAY
          call delay

          goto main_loop


;--------------------------------------------------------------------------
; slave mode
;--------------------------------------------------------------------------

          routine slave_mode

          call clear

          btfsc instr,1
          goto slave1

          movlw LEFT                    ; display left/right selection
          btfsc instr,0
          movlw RIGHT
          call show_character

          goto slave2

slave1    movlw TICK                    ; display correct/incorrect
          btfsc instr,0
          movlw CROSS
          call show_character

slave2    movlw (TX_REPEAT*BUS_INTRO)/d'100'
          bsf flags,IGNORE
          call delay
          bcf flags,IGNORE

          movlf d'60',timer

slave3    wait d'100',main_loop

          decfsz timer                  ; timeout ?
          goto slave3
          goto display_message          ; branch if yes


;--------------------------------------------------------------------------
; page #1
;--------------------------------------------------------------------------

          org h'200'


;--------------------------------------------------------------------------
; 1-wire bus read mode
;--------------------------------------------------------------------------

          routine bus_read

          clrf PORTA                    ; input mode
          movlw PORTA_IO
          tris_A
          clrf PORTB
          movlw PORTB_IO|(1<<BUS)
          tris_B

          retlw 0


;--------------------------------------------------------------------------
; 1-wire bus write mode
;--------------------------------------------------------------------------

          routine bus_write

          clrf PORTA                    ; output mode
          movlw PORTA_IO
          tris_A
          clrf PORTB
          movlw PORTB_IO
          tris_B

          retlw 0


;--------------------------------------------------------------------------
; delays for the number of 100us in w reg
;--------------------------------------------------------------------------

          routine bus_delay

LOOP      set  CLOCK/(d'10000'*d'16')

          movwf work1

bus1      movlf LOOP,work2
bus2      clrwdt                        ; [4]
          decfsz work2                  ; [4]
          goto bus2                     ; [8]

          decfsz work1
          goto bus1

          retlw 0


;--------------------------------------------------------------------------
; transmits an instruction in w reg on the 1-wire bus
;--------------------------------------------------------------------------

          routine tx_bus_

          movwf instr

          rrf instr,w                   ; parity bit
          xorwf instr,w
          andlw 1
          skpz
          bsf instr,2

;         call bus_read                 ; bus in use ?
;         bsf PORTB,BUS
;         clrwdt
;         btfss PORTB,BUS
;         goto tx3                      ; branch if yes

          call bus_write

LOOP      set  BUS_INTRO/BUS_CLOCK

          movlf LOOP,work3              ; fast pulse train
tx1       movlw 1<<BUS
          xorwf PORTB
          movlw BUS_CLOCK
          call bus_delay
          decfsz work3
          goto tx1

          bcf PORTB,BUS                 ; gap
          movlw BUS_DATA
          call bus_delay

          movlf d'4',work3              ; transmit bits

tx2       bcf PORTB,BUS                 ; clock
          movlw BUS_CLOCK
          call bus_delay
          bsf PORTB,BUS
          movlw BUS_CLOCK
          call bus_delay

          rrf instr                     ; data
          skpc
          bcf PORTB,BUS
          movlw BUS_DATA
          call bus_delay

          decfsz work3
          goto tx2

          call bus_read

tx3       page0

          retlw 0


;--------------------------------------------------------------------------
; receives an instruction on the 1-wire bus
;--------------------------------------------------------------------------

rx_bus    macro

          call bus_read

EDGES     equ  d'20'
LOOP      set  (EDGES*BUS_CLOCK*d'100'*(CLOCK/d'1000'))/(d'48'*d'1000')

          clrf work2                    ; count intro pulses
          movlf LOOP,work3

rx1       clrwdt                        ; [4]

          bsf PORTB,BUS                 ; sample bus [4]
          movlw 0                       ; [4]
          btfsc PORTB,BUS               ; [4]
          movlw 1                       ; [4]

          subwf work1                   ; edge ? [4]
          movwf work1                   ; [4]
          skpz                          ; [8]
          incf work2                    ; increment count if yes

          decfsz work3                  ; [4]
          goto rx1                      ; [8]

          movlw EDGES/2                 ; enough edges ?
          subwf work2
          bnc rx7                       ; branch if not

LOOP      set  (BUS_DATA/2*d'100'*(CLOCK/d'1000'))/(d'32'*d'1000')

          clrf work1                    ; wait for gap

rx2       decf work1
          bz rx7                        ; branch if timeout

          movlf LOOP,work3

rx3       bsf PORTB,BUS                 ; [4]
          clrwdt                        ; [4]
          btfsc PORTB,BUS               ; [8]
          goto rx2

          clrf work1                    ; [4]

          decfsz work3                  ; [4]
          goto rx3                      ; [8]

          movlf d'4',work3              ; receive bits

rx4       clrf work1                    ; wait for clock rising edge
rx5       decf work1
          bz rx7                        ; branch if timeout
          bsf PORTB,BUS
          clrwdt
          btfsc PORTB,BUS
          goto rx5
          clrf work1
rx6       decf work1
          bz rx7                        ; branch if timeout
          bsf PORTB,BUS
          clrwdt
          btfss PORTB,BUS
          goto rx6

          movlw BUS_CLOCK+BUS_DATA/2    ; sample data
          call bus_delay
          bsf PORTB,BUS
          clrc
          btfsc PORTB,BUS
          setc
          rrf instr

          decfsz work3
          goto rx4

          swapf instr

          rlf instr,w                   ; test parity bit
          xorwf instr,w
          movwf work1
          rrf instr,w
          xorwf work1,w
          andlw 1<<1
          bnz rx7

          btfsc instr,3                 ; test stop bit
          goto rx7

          movlw b'11'
          andwf instr

          page0

          goto slave_mode               ; branch if ok

rx7
          endm


;--------------------------------------------------------------------------
; delay, fed with the period in 1/100 s in w reg
;--------------------------------------------------------------------------

          routine delay_

          movwf loop

delay1    movlf pixels,FSR

          clrf work2

delay2    movfw work2
          page0
          index enable
          page1
          movwf work3

          clrf PORTA
          movlf PIXELS_MASK,PORTB

          movfw work3
          andlw ~(1<<AorB)

          btfsc work3,AorB
          goto delay3

          movwf PORTA
          xorlw PORTA_IO
          tris_A
          movlw PORTB_IO
          tris_B

          goto delay4

delay3    iorwf PORTB
          xorlw PORTB_IO
          tris_B
          movlw PORTA_IO
          tris_A

delay4    movfw 0
          andlw PIXELS_MASK
          xorwf PORTB

LOOP      set  CLOCK/(d'100'*d'36'*d'7')

          movlf LOOP,work3
delay5    clrwdt                        ; [4]
          movlw LOOP/2                  ; [4]
          subwf work3,w                 ; [4]
          skpz                          ; [4]
          goto delay6                   ; [8]
          movlw PIXELS_MASK
          btfss 0,WEIGHT
          movwf PORTB
delay6    decfsz work3                  ; [4]
          goto delay5                   ; [8]

          incf FSR

          incf seed

          incf work2
          movlw d'7'
          subwf work2,w
          bnz delay2

          btfsc flags,IGNORE
          goto delay7

          rx_bus                        ; instruction on 1-wire bus ?

delay7    decfsz loop
          goto delay1

          clrf PORTA                    ; re-initialise ports
          movlw PORTA_IO
          tris_A
          clrf PORTB
          movlw PORTB_IO
          tris_B

          page0

          retlw 0


;--------------------------------------------------------------------------
; polls the pushbuttons, returns NZ flag set if either pushbutton pressed
;--------------------------------------------------------------------------

          routine poll_

          clrf PORTA
          movlf PIXELS_MASK,PORTB

          movlw PORTA_IO&(~(1<<BUTTON1))
          tris_A

          clrf TMR0                     ; poll pushbutton 1
          bsf PORTA,BUTTON1
          nop
          bcf flags,PRESSED1
          tstf TMR0
          skpz
          bsf flags,PRESSED1
          bcf PORTA,BUTTON1

          movlw PORTA_IO                ; re-initialise port
          tris_A

          movlw PORTB_IO&(~(1<<BUTTON2))
          tris_B

          clrf TMR0                     ; poll pushbutton 2
          bsf PORTB,BUTTON2
          nop
          bcf flags,PRESSED2
          tstf TMR0
          skpz
          bsf flags,PRESSED2
          bcf PORTB,BUTTON2

          movlw PORTB_IO                ; re-initialise port
          tris_B

          movfw flags
          andlw PRESSED_MASK

          btfss flags,RELEASE           ; waiting for release ?
          goto pollb1                   ; branch if not

          skpnz                         ; wait for pushbutton to be released
          bcf flags,RELEASE
          bcf flags,PRESSED1
          bcf flags,PRESSED2
          setz

pollb1    skpz
          bsf flags,RELEASE             ; signal waiting for release

          page0

          retlw 0


;--------------------------------------------------------------------------
; clears the pixels
;--------------------------------------------------------------------------

          routine clear_

          clrf pixels+0
          clrf pixels+1
          clrf pixels+2
          clrf pixels+3
          clrf pixels+4
          clrf pixels+5
          clrf pixels+6

          page0

          retlw 0


;--------------------------------------------------------------------------
; shows the character in w reg
;--------------------------------------------------------------------------

          routine show_left_

          movwf work1

          movlf pixels+0,FSR

          goto show1


          routine show_right_

          movwf work1

          movlf pixels+4,FSR
show1     movlf d'3',work2

          goto show2


          routine show_character_

          movwf work1

          movlf pixels+0,FSR
          movlf d'7',work2

show2     movfw work1                   ; index into the font
          page0
          call lookup
          page1

          movwf 0

          incf work1

          incf FSR
          decfsz work2
          goto show2

          page0

          retlw 0


;--------------------------------------------------------------------------
; generates a pseudo random number
;--------------------------------------------------------------------------

          routine get_random_

          movfw rand_l
          iorwf rand_h,w
          bnz getr1

          movfw seed                    ; seed generator
          movwf rand_l
          xorlw h'ff'
          movwf rand_h

getr1     rlf rand_h,w                  ; calculate next in sequence
          xorwf rand_h,w
          movwf work1                   ; msb <= Q15 ^ Q14
          swapf rand_l,w
          btfsc rand_h,4
          xorlw h'80'                   ; msb <= Q12 ^ Q3
          xorwf work1
          rlf work1
          rlf rand_l
          rlf rand_h                    ; << 1 + (Q15 ^ Q14 ^ Q12 ^ Q3)

          page0

          retlw 0


;--------------------------------------------------------------------------
; calculates the psi-q factor
;--------------------------------------------------------------------------

          routine calc_factor_

          clrf work1                    ; get the standard deviation
          clrf work2
          clrf work3
calc1     movfw work3
          page0
          index sigma
          page1
          incf work3
          tstw
          bz calc2
          addwf work2
          skpnc
          incf work1
          movfw work1
          subwf flips+0,w
          bnc calc2
          bnz calc1
          movfw work2
          subwf flips+1,w
          bc calc1                      ; work3 <= sigma

calc2     clrc
          rrf flips+0,w
          movwf work1
          rrf flips+1,w
          movwf work2                   ; work1,work2 <= flips/2

          movfw hits+1
          subwf work2
          movfw hits+0
          skpc
          decf work1
          subwf work1                   ; work1,work2 <= flips/2 - hits

          btfss work1,7
          goto calc3
          comf work1
          comf work2
          incf work2
          skpnz
          incf work1                    ; work1,work2 <= abs(flips/2 - hits)

calc3     clrf count
calc4     incf count
          btfsc count,3
          goto calc5
          movfw work3
          subwf work2
          skpc
          decf work1
          btfss work1,7
          goto calc4                    ; count <= abs(hits - flips/2) / sigma

calc5     page0

          retlw 0


;--------------------------------------------------------------------------
; reset vector
;--------------------------------------------------------------------------

          ifdef __16C56A

          org h'3ff'

          goto main_entry

          endif


          end